Batch Script in Windows Server 2008 R2

Question

I need a batch batch script that checks the size of a folder. If it reaches some X GB, for eg : 10 GB, it should go and delete all the sub directories or files inside it.

I know this would be simple job to do in Linux. But I am quite unfamiliar with windows servers and writing batch scripts.

At the moment I am running a script that deletes files/folder every time it runs, something like this

set folder="C:\myfolder"
cd /d %folder%
for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)

But I want to delete files/folders only if it reaches some GB size for eg 10 or 12 gb.

Your first statement (in brief: _delete folder_) contradicts to the last one _delete files only_. — JosefZ, Jun 05 '15 at 06:18
Searching StackOverflow for [batch folder size](http://stackoverflow.com/search?q=batch+folder+size) gives 200+ answered results... — JosefZ, Jun 05 '15 at 06:29
Why not install cygwin and use the same commands you would use on Linux ? Or use something more modern like wsh or powershell which either already is or can be installed easily ? — Marged, Jun 05 '15 at 06:30

score 1 · Answer 1 · edited May 23 '17 at 11:51

On Windows server use powershell. Finding the size of a folder is then:

$size = (Get-ChildItem $FolderName -Recurse | Measure-Object -Property Length -Sum).Sum
if ($size > $Limit) {
    Remove-Item $FolderName -Recurse -Whatif
}

There is a really good explanation of why powershell is potentially more useful than a set of unix tools as the best answer for Is PowerShell ready to replace my Cygwin shell on Windows?

The -Whatif makes the Remove-Item safe as adding -WhatIf just reports what the command would do if executed.

MC ND · Answer 2 · 2015-06-05T10:32:28.783

For a batch solution

@echo off
    setlocal enableextensions disabledelayedexpansion
    rem      12345678901234567890
    set "pad=                    "

    for %%a in ("%~f1.") do set "target=%%~fa"

    set "limit=%~2"
    if not defined limit set "limit=10737418240"

    echo(Searching in [%target%] ....

    for /f "tokens=3" %%a in ('
        dir /s /-c /a "%target%"
        ^| findstr /i /r /c:"^  .*bytes$" 
    ') do set "size=%%a"

    set "limit=%pad%%limit%"
    set "size=%pad%%size%"

    echo(
    echo(.... limit [%limit:~-20%]
    echo(.... size  [%size:~-20%]
    echo(

    if "%size:~-20%" lss "%limit:~-20%" (
        echo Size is in range
        goto :eof
    )

    echo(Size is out of range. Cleaning ....
    pushd "%target%" && (
        rem rmdir . /s /q
        popd
    )

This batch file uses two arguments: the first one is the folder to process (by default the current folder) and the second one the size limit to check (by default 10GB).

A dir command in used to retrieve the full size under the indicated folder. The ouput from this comand is parsed with a for /f to get the needed data.

Batch files arithmetic is limited to a 2^31 max value. To handle greater values in conditions, the numbers need to be converted to padded strings to be compared.

The script only echoes information to console. You will need to uncomment the rmdir command that should remove the contents of the target folder.

score 0 · Answer 3 · answered Jun 05 '15 at 08:15

On Error Resume Next
Set fso = CreateObject("Scripting.FileSystemObject")

'make a new folder to delete
Set f = fso.CreateFolder("c:\New Folder")

'wait 30 secs to you can see it in explorer
wscript.sleep 30000

'Checking size
Set fldr = fso.GetFolder("c:\new folder")
Msgbox fldr.size

If fldr.size > 100000000000 then msgbox "too large"

fldr.delete

VBScript is designed for this.

Batch Script in Windows Server 2008 R2

3 Answers3