How to save .txt as Unicode or UTF-8 in VBA

Question

I want that all my files be saved in unicode or utf-8 format and not ANSI.

Here is the code:

Sub cvelle()
Dim iRow As Long
Dim iFile As Integer
Dim sPath As String
Dim sFile As String


For iRow = 1 To Cells(Rows.Count, "B").End(xlUp).Row
    iFile = FreeFile
    With Rows(iRow)
        sPath = "E:\" & .Range("B1").Value & "\"
        If Len(Dir(sPath, vbDirectory)) = 0 Then MkDir sPath
        sFile = .Range("D1").Value & ".txt"
        
        Open sPath & sFile For Output As #iFile
        Print #iFile, .Range("E1").Value
        Close #iFile
    End With
Next iRow
End Sub

Now, I thought that just inserting the code below would be enough.

sFile = .Range("D1").Value & ".txt",FileFormat:= _xlUnicodeText

But it gives me an error.

Answer 1

I know how to create a uncode txt file. Maybe you can try read data into variable > create a uncode txt > write data into txt >save txt

Dim fso As Object, myTxtFile As ObjectSet 
   fso = CreateObject("Scripting.FileSystemObject")
   Set myTxtFile = fso.CreateTextFile(fileName:="c:\123.txt", OverWrite:=True, Unicode:=True)

Answer 2

Function SaveTextToFile(ByVal txt$, ByVal filename$, Optional ByVal encoding$ = "windows-1251") As Boolean
    ' function saves text in txt in filename$
    On Error Resume Next: Err.Clear
    Select Case encoding$

        Case "windows-1251", "", "ansi"
            Set FSO = CreateObject("scripting.filesystemobject")
            Set ts = FSO.CreateTextFile(filename, True)
            ts.Write txt: ts.Close
            Set ts = Nothing: Set FSO = Nothing

        Case "utf-16", "utf-16LE"
            Set FSO = CreateObject("scripting.filesystemobject")
            Set ts = FSO.CreateTextFile(filename, True, True)
            ts.Write txt: ts.Close
            Set ts = Nothing: Set FSO = Nothing

        Case "utf-8noBOM"
            With CreateObject("ADODB.Stream")
                .Type = 2: .Charset = "utf-8": .Open
                .WriteText txt$

                Set binaryStream = CreateObject("ADODB.Stream")
                binaryStream.Type = 1: binaryStream.Mode = 3: binaryStream.Open
                .Position = 3: .CopyTo binaryStream        'Skip BOM bytes
                .flush: .Close
                binaryStream.SaveToFile filename$, 2
                binaryStream.Close
            End With

        Case Else
            With CreateObject("ADODB.Stream")
                .Type = 2: .Charset = encoding$: .Open
                .WriteText txt$
                .SaveToFile filename$, 2        ' saving in coding that you need
                .Close
            End With
    End Select
    SaveTextToFile = Err = 0: DoEvents
End Function

Answer 3

i personally use it at work because some pl reports have whole bunch of formats and tomake anadjustment you need it here is a function to read ```

Function LoadTextFromTextFile(ByVal filename$, Optional ByVal encoding$) As String
    ' functions loads in code  Charset$ from filename$
    On Error Resume Next: Dim txt$
    If Trim(encoding$) = "" Then encoding$ = "windows-1251"
    With CreateObject("ADODB.Stream")
        .Type = 2:
        If Len(encoding$) Then .Charset = encoding$
        .Open
        .LoadFromFile filename$        'load data from file 
        LoadTextFromTextFile = .ReadText        ' read text
        .Close
    End With
End Function

Answer 4

Hope this might save someone some time:

Sub ExportToTxt()
    Dim fileStream As Object
    Set fileStream = CreateObject("ADODB.Stream")
    fileStream.Charset = "utf-8"
    fileStream.Open

    Dim rangeToExport As Range
    Set rangeToExport = Worksheets("BPC-Processed").Range("A1").CurrentRegion

    Dim firstCol, lastCol, firstRow, lastRow As Integer
    firstCol = rangeToExport.Columns(1).Column
    lastCol = firstCol + rangeToExport.Columns.Count - 1
    firstRow = rangeToExport.Rows(1).row
    lastRow = firstRow + rangeToExport.Rows.Count - 1

    Dim r, c As Integer
    Dim str As String
    Dim delimiter As String
    For r = firstRow To lastRow
        str = ""
        For c = firstCol To lastCol
            If c = 1 Then
                delimiter = ""
            Else
                delimiter = vbTab ' tab
            End If
            str = str & delimiter & rangeToExport.Cells(r, c).Value
        Next c
        fileStream.WriteText str & vbCrLf ' vbCrLf: linebreak
    Next r

    Dim filePath As String
    filePath = Application.ThisWorkbook.Path & "\BPC-Processed.txt"
    fileStream.SaveToFile filePath, 2 ' 2: Create Or Update
    fileStream.Close
End Sub

Answer 5

Instead of typing a bunch of code, I figured out to make as default encoding as unicode here is how:

 1. Right click -> New -> Text Document 
 2. Open "New Text Document.txt". Do NOT type anything! 
 3. Go to "File -> Save As... " and choose UniCode under "Encoding:", press     "Save" and overwrite existing file. Close the file. 
 4. Rename "New Text Document.txt" to "UniCode.txt" 
 5. Copy "UniCode.txt" to "C:\WINDOWS\SHELLNEW" 
 6. Open Regedit and Navigate to HKEY_CLASSES_ROOT\.txt\ShellNew 
 7. Right click in the right window -> New -> "String Value" and rename it to  "FileName". 
 8. Double click on "FileName" and put "UniCode.txt" into "Value Data". 
 9. press OK It's finished. 

Thanks to all!