Which string concatenation operation is faster - "+" or string.Concat

Question

I have been reading different answers on which string concatenation operation is better. I read somewhere that "+" internally calls string.Concat method and string.Concat is faster between both. When I look at the IL code, it doesn't seem to suggest above statements.

For

string s1 = "1" + "2";

IL Code

.method private hidebysig static void  Main(string[] args) cil managed
{
  .entrypoint
  // Code size       8 (0x8)
  .maxstack  1
  .locals init ([0] string s1)
  IL_0000:  nop
  IL_0001:  ldstr      "12"
  IL_0006:  stloc.0
  IL_0007:  ret
} // end of method Program::Main

Also, I noticed from the IL code that "+" initializes only one string whereas string.Concat initializes two strings to concatenate. I also tried with multiple strings as well. In terms of using the memory, "+" seems to use just one string variable where as the other option uses more variables internally.

For,

string s1 = string.concat("1", "2");

IL Code

.method private hidebysig static void  Main(string[] args) cil managed
{
  .entrypoint
  // Code size       18 (0x12)
  .maxstack  2
  .locals init ([0] string s1)
  IL_0000:  nop
  IL_0001:  ldstr      "1"
  IL_0006:  ldstr      "2"
  IL_000b:  call       string [mscorlib]System.String::Concat(string,
                                                              string)
  IL_0010:  stloc.0
  IL_0011:  ret
} // end of method Program::Main

So can we conclude from above IL code that "+" is faster than "string.Concat" as it uses lesser variable for performing the same operation?

Whenever you need to compare the performance of two methods... well... compare them. Add a timer. Run the first one, run the second, and there you have it. Also, have a read here: http://ericlippert.com/2012/12/17/performance-rant/ — PiotrWolkowski, Jun 24 '15 at 12:25
http://coders-corner.net/2014/08/20/concatenate-strings-in-c-operator-vs-string-concat-vs-stringbuilder/ — Nitin Varpe, Jun 24 '15 at 12:25
This isn't really a fair comparison. As explained in the answer to [this question](http://stackoverflow.com/questions/288794/does-c-sharp-optimize-the-concatenation-of-string-literals), the compiler has simply evaluated the concatenation at compile time in your first example. It's a different story for multiple, non-constant arguments. — Charles Mager, Jun 24 '15 at 12:26
@dotctor computers stop working and the world comes to an end. — crashmstr, Jun 24 '15 at 12:27

Theodoros Chatzigiannakis · Accepted Answer · 2015-06-24T12:55:37.030

This comparison is wrong (assuming you are not interested in concatenation of string constants exclusively).

In your first snippet, the concatenation has already been performed by the C# compiler:

.method private hidebysig static void  Main(string[] args) cil managed
{
  .entrypoint
  // Code size       8 (0x8)
  .maxstack  1
  .locals init ([0] string s1)
  IL_0000:  nop
  IL_0001:  ldstr      "12"      // The strings are already concatenated in the IL.
  IL_0006:  stloc.0
  IL_0007:  ret
}

In your second snippet, the call to string.Concat remains:

.method private hidebysig static void  Main(string[] args) cil managed
{
  .entrypoint
  // Code size       18 (0x12)
  .maxstack  2
  .locals init ([0] string s1)
  IL_0000:  nop
  IL_0001:  ldstr      "1"
  IL_0006:  ldstr      "2"
  IL_000b:  call       string [mscorlib]System.String::Concat(string,
                                                              string)
  IL_0010:  stloc.0
  IL_0011:  ret
}

Therefore, it's meaningless to try to discern the performance of your two snippets using constants, because you'll get non-representative results.

In the general case, the C# compiler will compile a chain of + operators on strings as a single call to string.Concat. You can verify this by performing pretty much the same test that you did, with variables instead of constants.

As a demonstration, consider these two C# methods. One uses + to concatenate strings:

static string Plus(string a, string b, string c)
{
    return a + b + c;
}

The other calls string.Concat:

static string Concat(string a, string b, string c)
{
    return string.Concat(a, b, c);
}

Now look at their respective IL, using a Debug configuration:

.method private hidebysig static string Plus (
        string a,
        string b,
        string c
    ) cil managed 
{
    .locals init (
        [0] string V_0
    )

    IL_0000: nop
    IL_0001: ldarg.0
    IL_0002: ldarg.1
    IL_0003: ldarg.2
    IL_0004: call string [mscorlib]System.String::Concat(string,  string,  string)
    IL_0009: stloc.0
    IL_000a: br.s IL_000c

    IL_000c: ldloc.0
    IL_000d: ret
}

And:

.method private hidebysig static string Concat (
        string a,
        string b,
        string c
    ) cil managed 
{
    .locals init (
        [0] string V_0
    )

    IL_0000: nop
    IL_0001: ldarg.0
    IL_0002: ldarg.1
    IL_0003: ldarg.2
    IL_0004: call string [mscorlib]System.String::Concat(string,  string,  string)
    IL_0009: stloc.0
    IL_000a: br.s IL_000c

    IL_000c: ldloc.0
    IL_000d: ret
}

They are identical (except for their names). If we build using a Release configuration, we get shorter IL - but still identical for both methods.

In conclusion, in this special case, we can safely assume that we won't observe any performance difference between the two ways of expressing the same thing.

In the general case (where the IL isn't identical or near identical), we can't make any assumptions about performance based on our mental model of the CLR. Even if we do have a completely accurate mental model of the CLR, we must take under consideration that the bytecode ultimately gets compiled machine code, which is different from IL (for example, x86 code has registers but IL doesn't).

To reason about performance we use profilers instead, as they can give us practical, detailed metrics.

They are not "identical". One of them is named `Concat` another one is named `Plus` :D — Hamid Pourjam, Jun 24 '15 at 12:38

score 6 · Answer 2 · edited May 23 '17 at 12:30

There is nothing as Operator + in String class, so the whole + converted to String.Concat is done by C# compiler so they are identical.

Stop doing micro-optimizing or premature-optimization on your code. Try to write a code that performs correctly, then if you face a performance problem later then profile your application and see where is the problem. Strings are immutable. If you have a piece of code which have performance problem due to string concatenation you should consider using StringBuilder.

We should forget about small efficiencies, say about 97% of the time: premature optimization is the root of all evil. Yet we should not pass up our opportunities in that critical 3%

@doctor : I am not trying to micro-optimize, what I was trying to see is to ascertain the fact that "+" internally calls "string.Concat" and from the point of variable utilization "+" seems to be a better option..I believe I have got my answer. Thank you all! — m_d_p29, Jun 24 '15 at 12:53

Which string concatenation operation is faster - "+" or string.Concat

2 Answers2