Batch file to remove first 18 chars from txt file

Question

I have a .txt document with over 32,000 lines of commented machine code. It looks like this:

Display menu window
C0/000E:    E220        SEP #$20
C0/0010:    C210        REP #$10
C0/0012:    20640B      JSR $0B64
C0/0015:    20750B      JSR $0B75
C0/0018:    C220        REP #$20
C0/001A:    A90001      LDA #$0100

I need to convert the code as follows for compiling purposes:

; Display menu window
SEP #$20
REP #$10
JSR $0B64
JSR $0B75
REP #$20
LDA #$0100

Specifically, that means:

• Blank lines must remain unchanged.
• If a line starts with "C0/" then the first 18 characters are to be deleted, including tabs.
• Otherwise, it's a function title, so add a semi-colon followed by a space at the beginning (not mandatory).

Any help would be greatly appreciated.

Answer 1

So, the following code (This is in java btw) will read the text from the file you provide, process it, and if the line starts with C3/, will print the line with the first 18 characters removed, and the white space on the beginning and end trimmed off. If the line does not start with C3/ then the line will be printed as is. (FYI this java code is probably faster than a batch file in terms of processing your enormous text file, which is why i recommended java in the first place :P)

import java.io.*;


public class ClassName{
    public static void main(String args[])throws IOException{
        PrintWriter file_out = new PrintWriter("OutputFileName.txt");
        BufferedReader br = new BufferedReader(new FileReader("OriginalFileName.txt"));

        String line, temp, out = "";
        while((line = br.readLine()) != null){
            temp = line.substring(0,3);
            if(temp.equals("C3/")){
                out = line.substring(18, line.length()).trim();

                file_out.println(out);

            }else{
                file_out.println(line);
            }



        }
        file_out.close();
    }

}

Of course replace OutputFileName.txt and OriginalFileName.txt with your text files. To compile and run this you will need to install and setup JDK. To see how to do this, click here. You can also find numerous other tutorials on the web on how to setup and use JDK. After you setup JDK, save this code as ClassName.java, compile it, and run it. Make sure that this program is saved in the same folder as your input/output files.

Note: Normally i wouldn't give out code like this but i was bored and was feeling nice :)

Also, i highly recommend you try to program in java a bit yourself. It's a very interesting and versatile language. If you have any other questions, feel free to let met know :D.

Example input:

Display menu window
C3/000E:    E220        SEP #$20
C3/0010:    C210        REP #$10
C3/0012:    20640B      JSR $0B64
C3/0015:    20750B      JSR $0B75
C3/0018:    C220        REP #$20
C3/001A:    A90001      LDA #$0100

Example output:

Display menu window
SEP #$20
REP #$10
JSR $0B64
JSR $0B75
REP #$20
LDA #$0100

Answer 2

Use of regular expression replace will solve your problem in single line:

sed -i -- 's/C0\/.....................//g' <your_file_name>

That of course assumes you have sed. I did this in linux and the content of test.txt got replaced as you required.

You can try windows version of sed from this site:

http://gnuwin32.sourceforge.net/packages/sed.htm

Answer 3

The Batch file below is a different approach that may run faster than other similar methods, but this largely depends on the size of the file:

@echo off

for /F "tokens=1-2*" %%a in ('findstr /N "^" test.txt') do (
   for /F "tokens=1,2 delims=:/" %%d in ("%%a") do (
      if "%%e" equ "C3" (
         echo %%c
      ) else if "%%e" neq "" (
         echo ; %%e %%b %%c
      ) else (
         echo/
      )
   )
)

However, the fastest method is via a Batch-JScript hybrid script. Save the file below with .bat extension:

@set @Batch=1    /*
@cscript //nologo //E:JScript "%~F0" < test.txt
@goto :EOF & rem */

WScript.Stdout.Write(WScript.Stdin.ReadAll().replace
   (/^C3\/.{15}|^(..)/gm,function(A){return A.length==2?"; "+A:""}));

Answer 4

This batch file should meet your requirements. Just save it as whatever.cmd and run it with whatever.cmd file_to_process. Save the output by redirecting stdout, like whatever.cmd file_to_process > processed_file.

@echo off
set "DEL_TOKEN=C0/"
set "DEL_TOKEN_LEN=3"
set "CHARS_TO_REMOVE=18"
set "FILENAME=%~1"

SETLOCAL DisableDelayedExpansion
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ %FILENAME%"`) do (
    set "LINE=%%a"
    SETLOCAL EnableDelayedExpansion
    set "LINE=!LINE:*:=!"
    if not "!LINE!"=="" (
        if "!LINE:~0,%DEL_TOKEN_LEN%!"=="%DEL_TOKEN%" (
            set "LINE=!LINE:~%CHARS_TO_REMOVE%!"
        ) else (
            set "LINE=; !LINE!"
        )
    )
    echo(!LINE!
    ENDLOCAL
)

Line reader courtesy of jeb.

Answer 5

I generally use JREPL.BAT to do regular expression text modification within the Windows command line.

JREPL.BAT is a pure script (hybrid JScript/batch) utility that runs natively on any Windows machine from XP onward. Full documentation is embedded within the script.

A single line is all that is needed for your problem. Assuming your file is "test.in" and your output is "test.out", then:

jrepl "^C0/.{15}|^." "|; $&" /t "|" /f test.in /o test.out

If you want to overwrite the original, then use /o - instead.

The JREPL solution is very fast.

If you want pure batch, then you could use the following optimized solution:

@echo off
setlocal enableDelayedExpansion
for /f %%N in ('find /c /v "" ^<test.txt') do set "cnt=%%N"
<test.in >test.out (
  for /l %%N in (1 1 %cnt%) do (
    set "ln="
    set /p "ln="
    if "!ln:~0,3!" == "C0/" (set "ln=!ln:~18!") else if defined ln set "ln=; !ln!"
    echo(!ln!
  )
)

If you want to overwrite the original, then add the following line to the very end:

move /y test.out test.in >nul