batch file to compare Folder sizes in bytes

Question

Hard drives are big these days and I want to store all my pictures on it and some times check to see if I have added or moved any files out by mistake.

this one is the one that works close to what I need but I don't what it to show me all the folders, just my selected ones

How to list all folder with size via batch file

I need a simple Batch file that can do a byte count and compare it to a number that it should be echo, good or not and then same routine on my chosen folder.. thanks for the help in advance

set "folder=DVD-001 - 4,471,234,796" 

set "size=0

for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\

@echo foldername  !size! Bytes

IF !size! EQU 4471234796 (@echo good) ELSE (@echo oops)

:next folder

set "folder=DVD-002 - 4,590,775,746"

set "size=0

for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\

@echo foldername  !size! Bytes

IF !size! EQU 4590775746 (@echo good) ELSE (@echo oops)  

Answer 1

• Comparing to the predefined list of folders with sizes:

  @echo off
  setlocal enableDelayedExpansion
  
  for /f "delims=: tokens=1,2*" %%a in ('^
      echo DVD-001: 4471234796: f:\folder1 ^&
      echo DVD-002: 4590775746: d:\another folder ^&
      echo DVD-003: 1111111111: e:\folder 3 ^&
      echo DVD-004: 2222222222: c:\folder 4 ^
  ') do (
      set status=
  
      rem trim the path
      for /f "tokens=*" %%c in ("%%~c") do set folder=%%~c
      for /l %%c in (1,1,100) do if "!folder:~-1,1!"==" " set folder=!folder:~0,-1!
      for /l %%c in (1,1,100) do if "!folder:~-1,1!"=="\" set folder=!folder:~0,-1!
  
      rem trim dvd size
      for /f %%b in ("%%~b") do set dvdsize=%%~b
  
      rem get folder size
      set size=
      if exist "!folder!" (
          rem save penultimate line
          for /f "tokens=2,3*" %%s in ('dir "!folder!" /s /w /a 2^>^&1') do (
              set prev=!cur! & set cur=%%t
          )
          rem combine digit groups
          for /l %%s in (0,1,20) do (
              if "!prev:~%%s,1!" geq "0" if "!prev:~%%s,1!" leq "9" (
                  set size=!size!!prev:~%%s,1!
              )
          )
      ) else (
          set size=NOT FOUND
      )
      if !size!==!dvdsize! (
          echo GOOD %%a: !dvdsize! == !folder!
      ) else (
          if "!size!"=="" set size=ERROR
          echo OOPS %%a: !dvdsize! ^<^> !size! !folder!
      )
  )
  pause
  

• A two-way robocopy in list-only mode would be more reliable in case both folders exist:

  @echo off
  set DIR1=d:\somefolder (no trailing slash!)
  set DIR2=e:\anotherfolder (no trailing slash!)
  robocopy /L /njh /njs /ndl /s "%DIR1%" "%DIR2%" | find "%DIR1%"
  if errorlevel 1 (
      robocopy /L /njh /njs /ndl /s "%DIR2%" "%DIR1%" | find "%DIR2%"
      if errorlevel 1 (echo GOOD & goto DONE)
  )
  echo OOPS
  :DONE
  pause
  

  It will list the different files as well.