Batch Script Renaming File Prefix

Question

I have a batch file that essentially finds all the pdf files in a folder, and gives them a prefix. SO example: file1.pdf & file2.pdf. When the batch file runs, it adds a prefix, let's say "new" to each file. New - file1.pdf & New - file2.pdf.

I'm unsure of how to get this to check to see if this file already contains this prefix and skip it if true. Here's my current code:

set strPrefix=New - 

set fname=*.pdf

for %%f in (%fname%) Do echo Rename file "%%f" to "%strPrefix%%%f"

for %%f in (%fname%) Do ren "%%f" "%strPrefix%%%f"

Have you tried a [substring](http://stackoverflow.com/questions/636381/what-is-the-best-way-to-do-a-substring-in-a-batch-file)? — Bacon Bits, Aug 10 '15 at 14:28

dbenham · Accepted Answer · 2015-08-10T15:37:59.017

2

Use DIR /B to list the files and pipe the result to FINDSTR to remove the files that aready have the prefix. Process that result with FOR /F (instead of a simple FOR).

@echo off
setlocal
set "prefix=New - "
set "mask=*.pdf"

for /f "eol=: delims=" %%F in (
  'dir /b "%mask%" ^| findstr /vibc:"%prefix%"'
) do ren "%%F" "%prefix%%%F"

Or you could use my JREN.BAT regular expression file renaming utility to do things more simply. It is pure script (hybrid JScript/batch) that runs natively on any Windows machine from XP onward. Full documentation is embedded within the script.

The following command (for the command line) assumes JREN.BAT is in a folder that is listed within your PATH.

jren "^" "New - " /fm "*.pdf" /fx "New - *"

Use CALL JREN if you put the command within a batch script.

edited Aug 10 '15 at 15:37

answered Aug 10 '15 at 15:11

dbenham

127,446
28
251
390

1

Typo in `findstr /vibc:"%mask%"` should be `findstr /vibc:"%prefix%"`? The same in `ren`? – JosefZ Aug 10 '15 at 15:36
@JosefZ - Of course. How silly of me. All fixed. Thanks. – dbenham Aug 10 '15 at 15:38
I was actually trying your suggestion and found out that &mask& needed to be %prefix% and was coming back to tell you but you beat me to it :) – Tweak000 Aug 10 '15 at 15:48
@dbenham I can't seem to find the download link for JREN – Bricktop Sep 13 '21 at 05:05

score 0 · Answer 2 · edited Aug 10 '15 at 15:30

0

The following code extracts the beginning of the filename and compares it with your predefined prefix (in a case-insensitive manner):

set "strPrefix=New - "
set lenPrefix=6
set fname=*.pdf

setlocal EnableDelayedExpansion
for %%F in (%fname%) do (
  set "file=%%~nxF"
  if /i not "!file:~0,6!"=="%strPrefix%" (
    ren "%%~fF" "%strPrefix%%%~nxF"
  )
)
endlocal

The variable lenPrefix holds the length (number of characters) of the prefix, bacause there is no built-in function to get it.

edited Aug 10 '15 at 15:30

foxidrive

40,353
10
53
68

answered Aug 10 '15 at 15:02

aschipfl

33,626
12
54
99

This didn't appear to work. Nothing happens when it runs. – Tweak000 Aug 10 '15 at 15:27
Thanks for the fix, @foxidrive!! – aschipfl Aug 10 '15 at 16:17

Batch Script Renaming File Prefix

2 Answers2

Linked