Constantly monitor if a process is running

Question

I have the following code:

Dim p() As Process

Private Sub CheckIfRunning()
    p = Process.GetProcessesByName("skype") 'Process name without the .exe
    If p.Count > 0 Then
        ' Process is running
        MessageBox.Show("Yes, Skype is running")
    Else
        ' Process is not running
        MessageBox.Show("No, Skype isn't running")
    End If
End Sub

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    CheckIfRunning()
End Sub

And it works GREAT!

But I'm wondering how I would convert this to a monitoring application, to constantly check if the processes is running. Is it as simple as putting the check on a timer every 1 second, or is there a better, more efficient way to go about this.

In the end result, I'd like to have a label that says "Running", or "Not Running" based on the process, but I need something to watch the process constantly.

You could achieve this in several ways. I would personally spawn a worker thread that runs until stopped and monitors the service. However, you could use a variety of solutions to this problem. — Martin, Aug 13 '15 at 15:35
How do you feel about @keith's answer below? Do you think there is warrant to putting this check in it's own thread? Or is the task so minuscule that it isn't worth the effort? — level42, Aug 13 '15 at 16:04

score 5 · Answer 1 · edited May 23 '17 at 12:09

If you need the app running all the time, then you don't need a Timer at all. Subscribe to the Process.Exited() event to be notified when it closes. For instance, with Notepad:

Public Class Form1

    Private P As Process
    Private FileName As String = "C:\Windows\Notepad.exe"

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim ps() As Process = Process.GetProcessesByName(Path.GetFileNameWithoutExtension(FileName))
        If ps.Length = 0 Then
            P = Process.Start(FileName)
            P.EnableRaisingEvents = True
            AddHandler P.Exited, AddressOf P_Exited
        Else
            P = ps(0)
            P.EnableRaisingEvents = True
            AddHandler P.Exited, AddressOf P_Exited
        End If
    End Sub

    Private Sub P_Exited(sender As Object, e As EventArgs)
        Console.WriteLine("App Exited @ " & DateTime.Now)
        Console.WriteLine("Restarting app: " & FileName)
        P = Process.Start(FileName)
        P.EnableRaisingEvents = True
        AddHandler P.Exited, AddressOf P_Exited
    End Sub

End Class

That would keep it open all the time, assuming you wanted to open it if it wasn't already running.

If you don't want to open it yourself, and need to detect when it does open, then you could use WMI via the ManagementEventWatcher as in this previous SO question.

score 3 · Answer 2 · answered Aug 13 '15 at 15:39

3

I've done something similar to this to monitor an exe that I need to be running all the time, and to restart it if it was down. Mine was running as a Windows Service - that way it would start when windows booted and id never need to look after it.

Alternatively you could just create it as a console app and put it in your startup folder?

I had:

Sub Main()

    Do
        Check_server()
        Dim t As New TimeSpan(0, 15, 0)
        Threading.Thread.Sleep(t)
    Loop

End Sub


Public Sub Check_server()

    Dim current_pros() As Process = get_pros()
    Dim found As Boolean = False

    If Now.Hour < "22" Then
        For Each pro In current_pros
            If pro.ProcessName.ToLower = "Lorraine" Then
                found = True
                Exit For
            Else
                found = False
            End If
        Next
        If found Then
            Console.WriteLine("Server up")
        Else
            Console.WriteLine("Server down - restarting")
            restart_server()
        End If
    End If
End Sub

My "server" app was called Lorraine...Also a timer maybe better practice than having the thread sleep..

answered Aug 13 '15 at 15:39

Shovers_

497
2
13

How do you make windows service to run a GUI program? – Altiano Gerung Jul 31 '18 at 03:29
a GUI program that is interactive to the user? – Shovers_ Aug 02 '18 at 14:23
yes, I need to make sure my Interactive GUI program always up – Altiano Gerung Aug 03 '18 at 02:25
ok. That may be difficult. Possibly a separate question. The issue will be around the account thats running the service - If its SYSTEM, any process it starts will be ran in the SYSTEM context and not available to standard users of a system – Shovers_ Aug 03 '18 at 08:57
in fact: https://stackoverflow.com/questions/4278373/how-to-start-a-process-from-windows-service-into-currently-logged-in-users-sess – Shovers_ Aug 03 '18 at 08:58

score 1 · Answer 3 · answered Aug 13 '15 at 15:46

From my experience, a simple timer works best:

'Timer interval set to 1-5 seconds... no remotely significant CPU hit
Private Sub timerTest_Tick(sender As System.Object, e As System.EventArgs) Handles timerTest.Tick
    Dim p() As Process = Process.GetProcessesByName("Skype")
    lblStatus.Text = If(p.Length > 0, "Skype is running.", "Skype isn't running.")
End Sub

Your mileage may vary, but I don't like to deal with separate threads unless necessary.

Constantly monitor if a process is running

3 Answers3