count length of filenames in batch

Question

my problem is I want to count the length of multiple filenames and save this numbers into a file.

My approach is this:

@echo off
for %%i in (*.txt) do (
    set Datei=%%~ni
    call :strLen Datei strlen

    :strLen
    setlocal enabledelayedexpansion

    :strLen_Loop
    if not "!%1:~%len%!"=="" set /A len+=1 & goto :strLen_Loop
    (endlocal & set %2=%len%)

    echo.%strlen%>> tmp
)

The problem here is it only works for the first filename and after that it is stuck and does not go on to the next filename.

`goto` and labels don't work inside the loop. Move the corresponding parts of code outside the loop. — wOxxOm, Sep 10 '15 at 17:33
You may post the fixed code and the remark why it wasn't working as an answer then. — wOxxOm, Sep 10 '15 at 17:42
`>lengths.tmp (for %# in (*.txt) do @echo %#^|%~z#)` (in a batch, use `%%#` and `%%~z#`) — JosefZ, Sep 10 '15 at 20:33
To get the length of a string you might be interested in this excellent effort: [How do you get the string length in a batch file?](http://stackoverflow.com/a/5841587/5047996) — aschipfl, Sep 10 '15 at 21:14
@JosefZ, you are generating a list of file _sizes_, but not a list of _lengths of file paths_... — aschipfl, Sep 10 '15 at 23:44

JosefZ · Answer 1 · 2015-09-11T08:29:47.343

Just for another alternative of a one-line command:

for %# in (*.txt) do @for /F "delims=:" %G in ('(echo "%~f#"^&echo(^)^|findstr /O "^"') do @if %~G NEQ 0 ( <^NUL set /p "dummy=%~f#|%~z#|"&set /a %~G-5&echo()

or the same in a bit more readable form:

for %# in (*.txt) ^
do @for /F "delims=:" %G in ('(echo "%~f#"^&echo(^)^|findstr /O "^"') ^
do @if %~G NEQ 0 ( <^NUL set /p "dummy=%~f#|%~z#|"&set /a %~G-5&echo()

Unfortunately, unlike the cmd shell, set command does not display its result in a batch script. Therefore, we need to set a string length to an environment variable and then echo its value with delayed expansion enabled:

@ECHO OFF >NUL
SETLOCAL EnableExtensions EnableDelayedExpansion
rem file lengths:
rem for %%A in (*.txt) do echo Name:%%A, Length: %%~zA
rem full path lengths:
for %%# in (*.txt) do (
  for /F "delims=:" %%G in ('(echo "%%~f#"^&echo(^)^|findstr /O "^"') do (
    if %%~G NEQ 0 (
      set /a "length=%%~G-5"
      rem echo(%%~f#^|%%~z#^|!length!
      echo(%%~f#^|!length!
    )
  )
)

Very well piece of code, thank you. here a variant with filename.ext only (remove every x if you want filename only) `for %# in (*.txt) do @for /F "delims=:" %G in ('(echo "%~nx#"^&echo(^)^|findstr /O "^"') do @if %~nG NEQ 0 ( <^NUL set /p "dummy=%~nx#|"&set /a %~G-5&echo() ` — Paul, Sep 11 '15 at 15:46

score 2 · Answer 2 · answered Sep 11 '15 at 06:18

Just for another alternative, findstr can output the offset of each matching line. Using it over the dir output and substracting the offset of the previous line from the current one (and the CRLF at the end of the line), we get the length of the previous line / file name

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "lastOffset=0"
    for /f "tokens=1,* delims=:" %%a in ('(dir /b *.txt ^& echo(^) ^| findstr /o "^"') do (
        if %%a gtr 0 (
            set /a "size=%%a - lastOffset - 2"
            setlocal enabledelayedexpansion
            echo(!fileName! !size!
            endlocal
        )
        set "lastOffset=%%a"
        set "fileName=%%b"
    )

score 1 · Answer 3 · edited Mar 20 '17 at 10:04

A slightly modified how to do count length of file name.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
(
    for  /f "tokens=*" %%A in ('dir *.txt /B /S /A:-D ^| findstr /IV "_output.txt"') do (
        set "name=%%~nA" 
        @echo "!name!">"%TMP%\_Temp.txt"

        for %%I in ("%TMP%\_Temp.txt") do ( 
            set /a "length=%%~zI"
            set /a length-=4
            @echo !length!:'!name!'
        )
    )
)> _output.txt 2>&1
del "%TMP%\_Temp.txt"
MORE /C /P _output.txt
ENDLOCAL
EXIT /B 0

score 0 · Answer 4 · edited Sep 11 '15 at 16:10

0

well the solution was coming from you i just moved the parts out of the loop. the code is this:

@echo off
for %%i in (*.txt) do (
set Datei=%%~ni
call :strLen Datei strlen
)

:strLen
setlocal enabledelayedexpansion

:strLen_Loop
if not "!%1:~%len%!"=="" set /A len+=1
goto :strLen_Loop

(endlocal & set %2=%len%)
echo.%strlen%>> tmp

edited Sep 11 '15 at 16:10

Paul

2,620
2
17
27

answered Sep 11 '15 at 10:13

niCon

1
3

The script does not stop of itself. – Paul Sep 11 '15 at 15:28

count length of filenames in batch

4 Answers4