Batch: Array index returns blank

Question

In this piece of code I'm trying to make a list fit the screen in WinPE by alternating into two columns. But when I put !modelsvar[%increment%]:~20! in the echo it returns only ~20. Strange because !modelsvar[%%D]:~20! works fine. I've tried many variations of ! and % but no luck. Anyone know if there's is a specific rule that I'm missing?

I have setlocal enabledelayedexpansion enabled

set modelsx=%counter%
set /a counter=0

for /l %%D in (1,2,%modelsx%) do (
set /a counter+=1
set /a increment=!counter!+1
ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. !modelsvar[%increment%]:~20!
set /a counter+=1
)

score 1 · Accepted Answer · edited May 23 '17 at 10:27

1

for /l %%D in (1,2,%modelsx%) do (
   set /a counter+=1
   set /a increment=counter+1
   for %%X in (!increment!) do (
      ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. !modelsvar[%%X]:~20!
   )
   set /a counter+=1
)

Further details at Arrays, linked lists and other data structures in cmd.exe (batch) script

edited May 23 '17 at 10:27

Community

1
1

answered Oct 14 '15 at 15:27

Aacini

65,180
12
72
108

That works. Thank you. I suspected it had something to do with process order but i didn't think i could echo from two for loops in one line alternatively. – Einar Þórir Árnason Oct 14 '15 at 15:45

score 1 · Answer 2 · answered Oct 14 '15 at 15:39

You're expanding increment immediately within ECHO, that is like %increment%, so the returned value is the one before the for loop executes.

Here is another work-around:

set modelsx=%counter%
set /a counter=0

for /l %%D in (1,2,%modelsx%) do (
    set /a counter+=1
    set /a increment=!counter!+1
    call ECHO !counter!. !modelsvar[%%D]:~20!      !increment!. %%modelsvar[!increment!]:~20%%
    set /a counter+=1
)

Batch: Array index returns blank

2 Answers2