Changing desktop.ini doesn't update folder icon automatically in Windows

Question

I'm using this batch script to change the icons of all the folders and sub-folders to the .ico files that are located in the folders.

However the folder icons do not change in Explorer unless I manually rename desktop.ini file in Explorer to something else and then back to desktop.ini or change the letters to uppercase for example.

I even wrote a batch function to automatically rename the desktop.ini but it doesn't work.

What is the difference between renaming them manually and renaming it from a batch file and how can I make Explorer use the new desktop.ini?

@echo off

for /r %%I in (*.ico) do (
    attrib -r -s "%%~dpI." /S /D 

    if exist %%~dpIdesktop.ini (
        del "%%~dpIdesktop.ini"
    ) 
    >>%%~dpIdesktop.ini echo [.ShellClassInfo]
    >>%%~dpIdesktop.ini echo IconResource="%%~nI%%~xI",0

    attrib -h desktop.ini /S
    attrib +r -s "%%~dpI." /S /D        
)

After having logged off and on again, the new icon should be displayed (just to ensure the batch works)... — aschipfl, Oct 23 '15 at 19:00
Logging off/onn doesn't work. Only thing that works is manual renaming. — HumansAreDead, Oct 23 '15 at 19:31
See [Refresh Icon Cache Without Rebooting](http://superuser.com/a/499083) — wOxxOm, Oct 23 '15 at 20:02
Killing Explorer is a bit harsh. Read this http://www.winhelponline.com/blog/refresh-icon-cache-windows-7-quickly/. I bet there even is a trick which involves rundll32 ... — Marged, Oct 23 '15 at 20:19

score 5 · Answer 1 · answered Oct 23 '15 at 20:31

Use a shell function that will notify all running Explorer windows to use the updated desktop.ini. This API is exposed in VBScript via Shell.Application.NameSpace("folder\").MoveHere:

@echo off
for /r %%I in (*.ico) do (
    attrib -h -s -r "%temp%\desktop.ini" >nul
    (
        echo [.ShellClassInfo]
        echo IconResource="%%~nxI",0
    )>"%temp%\desktop.ini"
    attrib +h +s "%temp%\desktop.ini"
    (
        echo set shell = CreateObject^("Shell.Application"^)
        echo set folder = shell.NameSpace^("%%~dpI"^)
        echo folder.MoveHere "%temp%\desktop.ini", 4+16+1024
    )>"%temp%\updateIcon.vbs"
    cscript //nologo //b "%temp%\updateIcon.vbs"
)
pause

P.S. I forgot most of VB so whoever remembers it may rewrite the entire code in VBS (embedded).

score 0 · Answer 2 · edited Aug 19 '16 at 09:33

0

I am not a big fan of forcefully killing Explorer.exe but I think this will work in a batch file based on what I saw on a few other websites.

taskkill /fi "imagename eq explorer.exe" /f
CD /d %userprofile%\AppData\Local
DEL IconCache.db /a
START explorer.exe

edited Aug 19 '16 at 09:33

Gerold Meisinger

4,500
5
26
33

answered Oct 23 '15 at 20:05

Squashman

13,649
5
27
36

Changing desktop.ini doesn't update folder icon automatically in Windows

2 Answers2

Linked