Iterating over a string (8086 assembly)

Question

Okay, i started learning 8086 assembly like month ago, and up until now i didn't have much problems learning it, but now i am stuck with strings. The problem is how can i Iterate over a string in 8086 and manipulate the characters? Also i have a task for my microprocessors course to remove all the ' characters from a given string (the string "proce'so'r" in my code) and then compare the newly acquired string with the first one and check if they are equal . The thing is i don't even know how to iterate it. It really was not explained in class, so i ask for help here. Here is my code so far (just for string iteration and printing the characters and it does not work, don't know why):

data segment
 string db "proce'so'r"
ends

stack segment
    dw   128  dup(0)
ends

code segment
start:

    lea di, string
    mov cx, 10

    for:
        cmp cx, 0
        je end


        mov dl, [di]
        mov ah, 02h
        int 21h 

        inc di
        loop for     
    end:


mov ax, 4c00h
int 21h  

ends

end start

Answer 1

expanding on my comment: a more efficient loop structure would be:

data segment
 string db "proce'so'r"
 stringlen equ $-string   ; subtract current string's address from current address
ends

start:

    mov ax, data
    mov ds, ax     ; Assuming rkhb is correct about segments

    lea   di, string
    mov   cx, stringlen   ; having the assembler generate this constant from the length of the string prevents bugs if you change the string

    ;; if stringlen can be zero:
     ;  test cx,cx
     ;  jz end

    ;; .labels are "local" and don't end up as symbols in the object file, and don't have to be unique across functions
    ;; emu8086 may not support them, and this Q is tagged as 8086, not just 16bit DOS on a modern CPU.
    print_loop:
        mov   dl, [di]
        mov   ah, 02h  ; If int21h doesn't clobber ah, this could be hoisted out of the loop.  IDK.
        int   21h 

        inc   di
        dec   cx
        jg   print_loop  ;  or jne
    end:

          ;  Or save a register (and the mov to initialize it) with
          ;   cmp  di, offset string+stringlen 
          ;   jb   print_loop

         ;; loop print_loop  ; or save instruction bytes, but slower on modern CPUs

mov ax, 4c00h
int 21h

---

A more common way to handle strings is to terminate them with a zero-byte. So the loop bound would be test dl,dl / jnz, with no counter needed.

Also, note that using si as a source pointer and di as a dest pointer is typical.

---

You could copy your string while skipping a certain character by doing

    mov   dl, [si]
    inc   si
    cmp   dl, '\''   ; or write the value as a hex constant instead of a character literal
    je  nocopy
     mov   [di], dl
     inc   di
nocopy:

as part of your loop. At the start of the loop, you want si pointing to the first char in your input string, and di pointing to a buffer big enough to hold the result. The character to skip could be in a register, instead of hard-coded as an immediate operand to cmp.

If you really want to save code bytes, at the expense of speed on modern CPUs, you could use the string-move instructions lodsb / stosb, except that they load to / store from al.

Answer 2

You need to initialize DS to use the defined data segment.

Complete Solution:

DATA SEGMENT
 STRING DB "PROCE'SO'R"
ENDS

STACK SEGMENT
    DW   128  DUP(0)
ENDS

CODE SEGMENT
START:

    MOV AX,@DATA
    MOV DS,AX

    LEA DI, STRING
    MOV CX, 10H

    FOR:
        CMP CX, 0
        JE END

        MOV DL, [DI]
        MOV AH, 02H
        INT 21H 

        INC DI
        LOOP FOR     
    END:

MOV AX, 4C00H
INT 21H  

ENDS

END START

Note the following after Start:

    MOV AX,@DATA
    MOV DS,AX