How to fill a line with character x up to column y using Vim

Question

How can I fill the remainder of a line with the specified character up to a certain column using Vim? For example, imagine that the cursor is on column four and I want to fill the remainder of the current line with dashes up to column 80. How would I do that?

Answer 1

You can do 80Ax<Esc>d80| for a simpler solution.

Answer 2

Here's a function to implement what you ask, and slightly more.

• It fills the line from its current end of line, rather than the cursor position
• It forces a single space between what's currently on the line and the repeated chars
• It allows you to specify any string to fill the rest of the line with
• It uses vim's textwidth setting to decide how long the line should be (rather than just assuming 80 chars)

The function is defined as follows:

" fill rest of line with characters
function! FillLine( str )
    " set tw to the desired total length
    let tw = &textwidth
    if tw==0 | let tw = 80 | endif
    " strip trailing spaces first
    .s/[[:space:]]*$//
    " calculate total number of 'str's to insert
    let reps = (tw - col("$")) / len(a:str)
    " insert them, if there's room, removing trailing spaces (though forcing
    " there to be one)
    if reps > 0
        .s/$/\=(' '.repeat(a:str, reps))/
    endif
endfunction

Insert that into your .vimrc, and make a mapping to it, e.g.

map <F12> :call FillLine( '-' )

Then you can press F12 to apply the hyphens to the current line

Note: this could probably be easily extended to act on a selection in VISUAL mode, but currently works for single lines only.*

Answer 3

If I understand the question correctly, this can be accomplished like this: in normal mode subtract the cursor's current column position from the desired ending column, then type the result followed by 'i' to enter insert mode, then the character you want to fill the space with. End by returning to normal mode. For example, with the cursor at column four in normal mode, if you wanted to fill the rest of the line up to column 80 with dashes, type 76i- then Esc or Ctrl-[ to return to normal mode. This should result in 76 dashes starting in column 4 and ending in column 79.

Answer 4

If you have the virtualedit option set to block or all, you can create a visual selection (even over empty space) up to the desired column:
v80| (if virtualedit=all) or
<c-v>80| (if virtualedit=block)

Then replace the selected area with dashes: r-

It's probably helpful to start visual mode after the last character in the line by hitting l to avoid overwriting the last character in the line. If you are not using virtualedit=all, then you need to set virtualedit+=onemore so you can move one character beyond the end of line in normal mode.

Answer 5

One of the other answers here is: 80Ax<Esc>d80|. I initially started using it as a key mapping like this:

nnoremap <leader>- 80A-<Esc>d80<bar>

...but I didn't like how it leaves the cursor at the end of the line. Also, for narrow windows (e.g. just a little wider than 80 cells), it causes the entire window to scroll horizontally because the cursor briefly jumps to the end of the long line before it's trimmed back to 80. This is partially resolved by returning to the beginning of the line:

nnoremap <leader>- 80A-<Esc>d80<bar>0

...but then the screen will "flash" briefly while the cursor jumps offscreen and back (thus scrolling the window briefly to the right and back). To prevent this, we can temporarily use reverse insert mode (:h revins or :h ri) to keep the cursor onscreen while appending. Here's the full command as a key mapping:

nnoremap <leader>- :set ri<cr>80A-<esc>81<bar>d$0:set nori<cr>

Answer 6

This answer answers your question. Just replace len computation with your desired column number (+/- 1 may be, I never remember), and remove the enclosing double-quotes added by the substitution.

Answer 7

Using the textwidth value is also possible. It allows for different maximum line widths depending on filetype (check :h 'tw'). Here is what I now use, it appends a space after existing line content if present and will prompt for the string to use for the pattern:

function! FillLine() abort
    if &textwidth
        let l:str = input('FillLine>')
        .s/\m\(\S\+\)$/\1 /e  " Add space after content (if present).

        " Calculate how many repetitions will fit.
        let l:lastcol = col('$')-1  " See :h col().
        if l:lastcol > 1
            let l:numstr = float2nr(floor((&textwidth-l:lastcol)/len(l:str)))
        else
            let l:numstr = float2nr(floor(&textwidth/len(l:str)))
        endif

        if l:numstr > 0
            .s/\m$/\=(repeat(l:str, l:numstr))/  " Append repeated pattern.
        endif
    else
        echohl WarningMsg
        echom "FillLine requires nonzero textwidth setting"
        echohl None
    endif
endfunction

You can map it for quick access of course. I like:

nnoremap <Leader>' :call FillLine()<Cr>

Note that the calculation assumes simple ASCII characters are being inserted. For more complicated strings, len(l:str) might not work. From :h strlen():

If you want to count the number of multi-byte characters use strchars().
Also see len(), strdisplaywidth() and strwidth().

Answer 8

You can insert first your dashes and then go to the first character and enter your text in replace mode: 80i-Esc0R

if you don't want to type the text, first delete the line with 0D, use 80i-Esc to insert the dashes and 0RCTRL+r " to paste the contents of the unamed register in replace mode.

Answer 9

I actually stumbled across this looking to align columns. Just in case anyone else does the same, this thread might be useful: How to insert spaces up to column X to line up things in columns?