How do I add the -j option to my ctest cmake file?

Question

I would like to run parallel jobs when running ctest. I tried setting

set(CTEST_PARALLEL_LEVEL 8)

in

CTestCustom.cmake.in

but this didn't change the command line options after I re-generated my build files.

I am on windows, using visual studio.

`CTEST_PARALLEL_LEVEL` should be provided as an environment variable (see [cmCTest.cxx](https://github.com/Kitware/CMake/blob/master/Source/cmCTest.cxx#L2535)). Have you tried `set(ENV{CTEST_PARALLEL_LEVEL} 8)`? — Florian, Nov 27 '15 at 15:33
Thanks. I tried this but it didn't seem to help. Where should I set this in my files? In VIsualStudio, RUN_TESTS creates a post-build step that runs the ctest exe. I am hoping to add a line in my cmake files that adds a `-j 8` command line parameter to this post-build step — Jacko, Nov 27 '15 at 15:49

score 8 · Accepted Answer · edited May 23 '17 at 12:24

You can't change the command line that is used when you build RUN_TESTS on Visual Studio. There are no options in the code (see cmGlobalGenerator::CreateDefaultGlobalTargets()).

I see the following possible approaches:

Set the CTEST_PARALLEL_LEVEL environment variable globally in your Windows (so it's just part of you machines CMake/CTest configuration) or add a start script for your Visual Studio.
- Can I set an environment variable for an application using a shortcut in Windows?

Create your own target with something like

add_custom_target(
    RUN_TESTS_J8 
        COMMAND ${CMAKE_CTEST_COMMAND} -j 8 -C $<CONFIGURATION> --force-new-ctest-process 
        WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
)

CMake: setting an environmental variable for ctest (or otherwise getting failed test output from ctest/make test automatically)

And mayby group it together with the other predefined targets

set_property(GLOBAL PROPERTY USE_FOLDERS ON)
set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMake")
set_property(TARGET RUN_TESTS_J8 PROPERTY FOLDER "CMake")

Combining build & run as a POST_BUILD step for the tests itself
```
add_custom_command(
    TARGET MyTest
    POST_BUILD
       COMMAND ${CMAKE_CTEST_COMMAND} -C $<CONFIGURATION> -R "^MyTest$" --output-on-failures
       WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
)
```
Then it would be - as being part of the normal build - by itself executed in parallel.
- Global custom target in CMake
- How to run ctest after building my project with cmake

More References

Using cmake how do I get verbose output from ctest?

Wow, thanks for all of this information. I decided on the simplest approach from your suggestions - set a windows env variable. This works great. — Jacko, Nov 28 '15 at 01:52

How do I add the -j option to my ctest cmake file?

1 Answers1