VB.NET combination Array x2

Question

I would like all possible combinations from two string arrays.

Both arrays must have same length.
Result must keep order

For example :

dim lStr1() as string = {"One", "Two", "Three"}
dim lStr2() as string = {"EditOne", "EditTwo", "EditThree"}

dim res() as string = myAwesomeFunction(lStr1, lStr2)

// res :
One Two Three
One Two EditThree
One EditTwo Three
One EditTwo EditThree
EditOne Two Three
EditOne Two EditThree
EditOne EditTwo Three
EditOne EditTwo EditThree

It's like the binary composition of 2 arrays of strings.

`all possibilities` would be 6! (or 720) unless there is some constraint. But it appears there are some constraints since the sample results only have 3 elements — Ňɏssa Pøngjǣrdenlarp, Dec 15 '15 at 14:49
you right that's not all possibilities, because i have to keep order ! — Testman, Dec 15 '15 at 14:52
the problem is i didn't find constraints exept it's like binary system between 2 strings arrays — Testman, Dec 15 '15 at 15:23
You havent defined all the rules yourself, so we would be gussing at what you want. for instance, what about `EditTwo Two Three`? — Ňɏssa Pøngjǣrdenlarp, Dec 15 '15 at 15:25
dunno how explain but only one column in both array must be use, that's the hard point here :s — Testman, Dec 15 '15 at 15:31
`dunno how explain` **thats** the problem! every one of the samples uses **at least two** elements from each array — Ňɏssa Pøngjǣrdenlarp, Dec 15 '15 at 15:32
only one column in both array, sry for my bad english, i mean column, index, can't use index 1 in the first array, and index 1 in the second array — Testman, Dec 15 '15 at 15:35
That's why the first word is always One or EditOne in the result, because it's the first index of the first or second array — Testman, Dec 15 '15 at 15:36
thats is a conststraint - a rule - and means that you want far, far less than "all possibilities". Write them all down on a piece of paper and when you are done, the code will almost write itself — Ňɏssa Pøngjǣrdenlarp, Dec 15 '15 at 15:53

Blackwood · Answer 1 · 2015-12-15T17:05:40.237

The following code will produce the array in your example. It should work for any pair of input arrays. The function checks that the input arrays are of the same length.

The GetPermutations function is taken from a more general class I use for generating permutations of numbers. It returns arrays of total Integers between 0 and choose - 1, and being an Iterator function, it returns the next array each time it is called.

In order to match your example, I returned an array of String where each element is a single string consisting of each of the selected strings separated by spaces. You may find it more useful to return a List(Of String()) or even a List(Of List(Of String))

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim lStr1() As String = {"One", "Two", "Three"}
    Dim lStr2() As String = {"EditOne", "EditTwo", "EditThree"}

    Dim res() As String = myAwesomeFunction(lStr1, lStr2)
End Sub

Function MyAwesomeFunction(lStr1() As String, lStr2() As String) As String()
    Dim combos As New List(Of String)
    If lStr1.Length <> lStr2.Length Then Throw New ArgumentException("Arrays must have the same length")
    For Each combo() As Integer In GetPermutations(lStr1.Length, 2)
        Dim elem As New List(Of String)
        For i As Integer = 0 To combo.Length - 1
            elem.Add(If(combo(i) = 0, lStr1(i), lStr2(i)))
        Next
        combos.Add(String.Join(" ", elem))
    Next
    Return combos.ToArray
End Function

Public Iterator Function GetPermutations(choose As Integer, total As Integer) As IEnumerable(Of Integer())
    Dim totals() As Integer = Enumerable.Repeat(Of Integer)(total, choose).ToArray
    Dim value(choose - 1) As Integer

    Do
        Yield value
        For index As Integer = choose - 1 To 0 Step -1
            value(index) += 1
            If value(index) < totals(index) Then Continue Do
            value(index) = 0
        Next
        Exit Do
    Loop
End Function

Maybe `GetPermutations(3, 2)` should be `GetPermutations(lStr1.Length, 2)`? — SysDragon, Dec 15 '15 at 17:04

score 1 · Accepted Answer · edited Jan 08 '16 at 07:06

1

Here's another solution. Since only 2 arrays are involved, we can bit-fiddle to get all of the "combinations". The & " " is just to format the output to match the example.

Private Function myAwesomeFunction(Array1() As String, Array2() As String) As String()
    If Array1.Length <> Array2.Length Then
        Throw New ArgumentException("Array lengths must be equal.")
    End If
    Dim combos(CInt(2 ^ Array1.Length) - 1) As String
    For i As Integer = 0 To combos.Count - 1
        For j = 0 To Array1.Length - 1
            If (i And (1 << j)) > 0 Then
                combos(i) += Array2(j) & " "
            Else
                combos(i) += Array1(j) & " "
            End If
        Next
    Next
    Return combos
End Function

edited Jan 08 '16 at 07:06

SysDragon

9,692
15
60
89

answered Dec 15 '15 at 17:53

JerryM

910
6
9

isn't better to use If Array1.Length <> Array2.Length Then to compare size of array ? what is the difference between both ? – Testman Dec 16 '15 at 09:21
Length vs Count. According to [this](http://stackoverflow.com/questions/2521592/difference-between-ienumerable-count-and-length), the answer is, "yes!" Good idea! – JerryM Dec 16 '15 at 21:38

VB.NET combination Array x2

2 Answers2