Parsing html in haskell

Question

I'm trying to parse the a links from the main part (<article>) of a blog post. I have adapted what I found on FPComplete but nothing is printed out. (The code does not work as far as I can see as running it on the online IDE and with the Bing target also produces no links.)

In GHCI I can simulate the first line of parseAF and that gets me a large record, which I take to be correct. But cursor $// findNodes &| extractData returns []

I've tried regex but that wasn't happy trying to find such a long piece of text.

Can anyone help?

{-# LANGUAGE OverloadedStrings #-}

module HtmlParser where

import Network.HTTP.Conduit (simpleHttp)
import Prelude hiding (concat, putStrLn)
import Data.Text (concat)
import Data.Text.IO (putStrLn)
import Text.HTML.DOM (parseLBS)
import Text.XML.Cursor (Cursor, attribute, element, fromDocument, ($//), (&//), (&/), (&|))

-- The URL we're going to search
url = "http://www.amsterdamfoodie.nl/2015/wine-beer-food-restaurants-troost/"

-- The data we're going to search for
findNodes :: Cursor -> [Cursor]
findNodes = element "article" &/ element "a"

-- Extract the data from each node in turn
extractData = concat . attribute "href"

cursorFor :: String -> IO Cursor
cursorFor u = do
     page <- simpleHttp u
     return $ fromDocument $ parseLBS page

-- Process the list of data elements
processData = mapM_ putStrLn

-- main = do
parseAF :: IO ()
parseAF = do
     cursor <- cursorFor url
     processData $ cursor $// findNodes &| extractData

UPDATE After more exploring it seems that the problem lies with element "article". If I replace that with element "p", which is OK in this instance as the only ps are in the article anyway, then I get my links. Pretty weird....!!

If I look for the source for that website the only `
` tag doesn't actually contain any links in it, it would appear that it's actually populated by javascript that runs after the HTML is loaded. — bheklilr, Dec 16 '15 at 15:36
Eh No. `
` runs from line 185 to 267 and includes numerous links - some in the text and some wrapped by wordpress around images (which I actually don't need) — Simon H, Dec 16 '15 at 15:54
Ah, yes, you would appear to be correct. Can you verify that when you download it with `simpleHttp` that you get the same content? I would try it myself but I'm currently behind a corporate proxy that makes it difficult to do that. — bheklilr, Dec 16 '15 at 15:57

Michael Szvetits · Answer 1 · 2016-08-01T09:46:13.377

6

I think you can do this in a very readable way with HXT by composing filters:

{-# LANGUAGE Arrows #-}

import Text.XML.HXT.Core
import Text.XML.HXT.Curl
import Text.XML.HXT.TagSoup

links url = extract (readDocument
  [ withParseHTML yes
  , withTagSoup
  , withCurl      []
  , withWarnings  no
  ] url)

extract doc = runX $ doc >>> xmlFilter "article" >>> xmlFilter "a" >>> toHref

xmlFilter name = deep (hasName name)

toHref = proc el -> do
   link    <- getAttrValue "href" -< el
   returnA -< link

You can call this in the following way:

links "http://www.amsterdamfoodie.nl/2015/wine-beer-food-restaurants-troost/"

edited Aug 01 '16 at 09:46

answered Dec 16 '15 at 17:43

Michael Szvetits

364
1
2
11

Does assume the html is xml compliant? – doron Dec 16 '15 at 17:54
1

Since the option "withParseHTML" is set, an HTML parser is used instead of an XML parser. So it is assumed to be valid HTML. – Michael Szvetits Dec 16 '15 at 18:04
1

A bit more readable still with the redundant parents in `extractLinks` removed. – Rein Henrichs Dec 16 '15 at 18:17
1

You are right, I removed the unnecessary parentheses. – Michael Szvetits Dec 16 '15 at 18:28
Hey, thanks. I'll try it tomorrow. I suppose we should consider ourselves lucky to have such a choice of tools but it does make the density of examples to work from low – Simon H Dec 16 '15 at 18:33
1

Might I ask why, in the definition of `extractLinks` you use a return in the end? I think a bind with a return makes it identity, so we can just ignore that return? – awllower Aug 01 '16 at 04:54

score 2 · Answer 2 · answered Dec 17 '15 at 08:43

2

OK, so the problem was that &/ only looks at immediate children, whereas &// will go through all descendants

findNodes = element "article" &// element "a"

answered Dec 17 '15 at 08:43

Simon H

20,332
14
71
128

Parsing html in haskell

2 Answers2

Linked