Need to remove numbers in parentheses and parentheses

Question

I have a spreadsheet in which a column has string data (names) followed by numbers in parentheses; i.e., (9815536). These numbers are not constant in length. I need to get rid of the numbers in the parentheses and the parentheses. I've tried using Columns().Cells.Replace funtion to no avail. Is there a way to use a regular expression to do this? A cell example would look like:

Column A
John Doe (9815536)
Sam Smith (12906)
...

Code I've tried looks like:

Columns("A:A").Select
    Selecton.Replace What:="\([0-9]*\), _
    Replacement:="", LookAt:=xlPart, SearchOrder:=xlByRows, _
    MatchCase:=False, SearchFormat:=False, _
    ReplaceFormat:=False

You could use a simple formula `=TRIM(LEFT(A1,FIND("(",A1)-1))` — Scott Craner, Jan 23 '16 at 18:02
or loop through the column in vba and use `cell = trim(split(cell,"(")(0))` were `cell` is the reference. — Scott Craner, Jan 23 '16 at 18:04
If you really want to use regex then you need to look [HERE](http://stackoverflow.com/questions/22542834/how-to-use-regular-expressions-regex-in-microsoft-excel-both-in-cell-and-loops) on its proper usage. — Scott Craner, Jan 23 '16 at 18:12

score 1 · Answer 1 · edited Jun 20 '20 at 09:12

A quick way to implement this is to use

a regexp

and a variant array in VBA.

Using code based on my Article Using Variant Arrays in Excel VBA for Large Scale Data Manipulation

Sub KillNumParen()
Dim rng1 As Range
Dim rngArea As Range
Dim lngRow As Long
Dim lngCol As Long
Dim lngCalc As Long
Dim objReg As Object
Dim X()


On Error Resume Next
Set rng1 = Application.InputBox("Select range for the replacement of non-number", "User select", Selection.Address, , , , , 8)
If rng1 Is Nothing Then Exit Sub
On Error GoTo 0

'See Patrick Matthews excellent article on using Regular Expressions with VBA
Set objReg = CreateObject("vbscript.regexp")
objReg.Pattern = "\(\d+\)"
objReg.Global = True

'Speed up the code by turning off screenupdating and setting calculation to manual
'Disable any code events that may occur when writing to cells
With Application
    lngCalc = .Calculation
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
    .EnableEvents = False
End With

'Test each area in the user selected range

'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
For Each rngArea In rng1.Areas
    'The most common outcome is used for the True outcome to optimise code speed
    If rngArea.Cells.Count > 1 Then
       'If there is more than once cell then set the variant array to the dimensions of the range area
       'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
        X = rngArea.Value2
        For lngRow = 1 To rngArea.Rows.Count
            For lngCol = 1 To rngArea.Columns.Count
                'replace the leading zeroes
                X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), vbNullString)
            Next lngCol
        Next lngRow
        'Dump the updated array sans leading zeroes back over the initial range
        rngArea.Value2 = X
    Else
        'caters for a single cell range area. No variant array required
        rngArea.Value = objReg.Replace(rngArea.Value, vbNullString)
    End If
Next rngArea

'cleanup the Application settings
With Application
    .ScreenUpdating = True
    .Calculation = lngCalc
    .EnableEvents = True
End With

Set objReg = Nothing
 End Sub

Need to remove numbers in parentheses and parentheses

1 Answers1