Picture added via VBA (Powerpoint) gets insertet into placeholder

Question

I've got a Powerpoint 2010 Macro to insert a specific picture to a fixed place on the active slide.

Dim oSlide As Slide
Dim oPicture As Shape

' Set oSlide to the active slide.
Set oSlide = Application.ActiveWindow.View.Slide

' Insert Image to Footer
 Set oPicture = oSlide.Shapes.AddPicture("PathToFile.png", _
  msoFalse, msoTrue, 630, 390, 15, 15)

' Move the picture to the center of the slide. Select it.
With ActivePresentation.PageSetup
  oPicture.Select
  oPicture.Name = "Dokumentverknüpfung"
End With

This code works fine if there is no unused placeholder on the slide. If there is a placeholder the Picture automatically gets inserted into this placeholder.

Is there a way to tell the script to avoid placeholders and just accept the given coordinates?

Thank you, Jens

Jamie Garroch - MVP · Accepted Answer · 2018-11-28T21:21:40.237

There is no way to explicitly tell PowerPoint not to use populate empty placeholders with pictures but you can stop it from doing so by making sure that there are no empty placeholders. If you call the sub ProtectEmptyPlaceholders before and after inserting your picture, then the picture gets inserted as a new shape.

Sub InsertPicture()
  Dim oSlide As Slide
  Dim oPicture As Shape

  ' Set oSlide to the active slide.
  Set oSlide = Application.ActiveWindow.View.Slide

  ' Protect empty placeholders from being auto-filled by PowerPoint
  ProtectEmptyPlaceholders oSlide, True

  ' Insert Image to Footer
   Set oPicture = oSlide.Shapes.AddPicture("PathToFile.png", _
    msoFalse, msoTrue, 630, 390, 15, 15)

  ' Reset empty placeholders
  ProtectEmptyPlaceholders oSlide, False

  ' Move the picture to the centre of the slide. Select it.
  With ActivePresentation.PageSetup
    oPicture.Select
    oPicture.Name = "Dokumentverknüpfung"
  End With
End Sub

' Purpose:  Adds dummy text to empty placeholders so that pictures can
'           be inserted without PowerPoint automatically placing them
'           within the first empty placeholder that supports pictures.
' Inputs:   oSld - the slide to process.
'           bProtect - if true, adds the dummy text to empty
'           placeholders and if false, deletes the dummy text from.
' Author:   Jamie Garroch of YOUpresent.co.uk 04MAR2016
Sub ProtectEmptyPlaceholders(oSld As Slide, bProtect As Boolean)
  Const sText As String = "PROTECTED"
  Dim oShp As Shape
  For Each oShp In oSld.Shapes
    If oShp.Type = msoPlaceholder Then
      If oShp.PlaceholderFormat.ContainedType = msoAutoShape Then
        If bProtect And Not oShp.TextFrame2.HasText Then oShp.TextFrame2.TextRange.text = sText
        If Not bProtect And oShp.TextFrame2.TextRange.text = sText Then oShp.TextFrame2.DeleteText
      End If
    End If
  Next
End Sub

Wow, thanks for the fast reply! This did it, now the macro works like it should :-) — Schmoozer, Mar 09 '16 at 12:34
You're welcome Jens. Glad to help out and glad it worked for you. — Jamie Garroch - MVP, Mar 09 '16 at 17:43
Note that this solution will not work if the placeholder accepts only pictures (i.e., it is not a multi-purpose placeholder). I also believe this will not work if the placeholder is multi-purpose and already contains non-text content (it would either clear the existing placeholder content, throw an error, or fail silently). — OfficeAddinDev, Nov 28 '18 at 15:46

OfficeAddinDev · Answer 2 · 2018-11-28T16:36:57.940

Try adding the picture to a new, temporary slide with a blank layout that contains no placeholders whatsoever. Then, cut the picture and paste it onto the original slide, and delete the temporary slide.

sldTemp = pres.Slides.Add(1, PowerPoint.PpSlideLayout.ppLayoutBlank)

The advantages of this approach are that (a) it works whether the placeholders are multi-purpose or picture-specific and, to a lesser extent, (b) it not does require looping through all shapes on the slide twice. The disadvantage is that you'll see some screen flicker as the temporary slide is inserted and deleted.

Update:

Here is perhaps a better approach that avoids inserting a blank slide. After inserting the picture, check to see if the newly inserted shape type is a placeholder. If so, then we need to Cut() the picture and paste it back onto the slide and adjust some of the shape's properties:

shpNew = Selection.SlideRange.Shapes.AddPicture(strImagePath, Office.MsoTriState.msoFalse, Office.MsoTriState.msoTrue, x, y)
If shpNew.Type = Office.MsoShapeType.msoPlaceholder Then
    'PowerPoint put the picture into a placeholder, against our wishes
    shpNew.Cut()
    ppApp.ActiveWindow.View.Paste()
    shpNew = ppApp.ActiveWindow.Selection.ShapeRange(1)
    With shpNew
        With .PictureFormat
            .CropBottom = 0
            .CropLeft = 0
            .CropRight = 0
            .CropTop = 0
        End With
        .ScaleHeight(1, Office.MsoTriState.msoTrue)
        .ScaleWidth(1, Office.MsoTriState.msoTrue)
        .Top = y
        .Left = x
    End With
End If

Picture added via VBA (Powerpoint) gets insertet into placeholder

2 Answers2