Windows Batch: Chained IF ELSE with Prompts

Question

I'm trying to write a windows batch script to do some work for me. Here is the code:

@echo off

cls

set /P AA="Is this information correct (Y/[N]) ? "
if /I "%AA%" == "Y" (

    echo Setting up %DATE% %TIME% ...

    echo Copying stuff to the places ...

    set /P BB="Overwrite (Y/[N]) ? "
    if /I "%BB%" == "Y" (

        echo Executing xxx ...

    ) else echo NOPE1 [%BB%]

    set /P CC="Overwrite (Y/[N]) ? "
    if /I "%CC%" == "Y" (

        echo Executing xxx ...

    ) else echo NOPE2 [%CC%]

    echo All set !

) else echo Setup aborted [%AA%] !

pause

The 2nd and 3rd answers are always empty, and when I remove the quotes from the prompt it blames the `?' character. What is wrong with the code ?

Thanks.

you'll need [delayed expansion](http://ss64.com/nt/delayedexpansion.html) — npocmaka, Apr 04 '16 at 13:06
short demo of [delayed expansion](http://stackoverflow.com/a/30284028/2152082) — Stephan, Apr 04 '16 at 13:07

Yore · Accepted Answer · 2016-04-04T13:34:24.950

This is kind of nonsense, but anyways, due to the 'Delayed Expansion' I modified the code to:

@echo off
Setlocal EnableDelayedExpansion

cls

set /P AA="Is this information correct (Y/[N]) ? "
if /I "%AA%" == "Y" (

    echo Setting up %DATE% %TIME% ...

    echo Copying stuff to the places ...

    set /P BB="Overwrite (Y/[N]) ? "
    if /I "!BB!" == "Y" (

        echo Executing xxx ...

    ) else echo NOPE1 [!BB!]

    set /P CC="Overwrite (Y/[N]) ? "
    if /I "!CC!" == "Y" (

        echo Executing xxx ...

    ) else echo NOPE2 [!CC!]

    echo All set !

) else echo Setup aborted [%AA%] !

pause

And it's working ! Thanks npocmaka and Stephan

Windows Batch: Chained IF ELSE with Prompts

1 Answers1