How to find the biggest digit in a number in Prolog?

Question

I have an easy task, but somehow I haven't solved it in over an hour. This recursion I am doing isn't working, I'm stuck in an infinte loop. It should compare the last digit of a number with every other and remember the biggest one. Would really like to know why is my logic faulty and how to solve this problem.

This is my try on it:

maxDigit(X,X):-
   X<10.
maxDigit(X,N):-
   X1 is X//10,
   X2 is X mod 10,
   maxDigit(X1,N1),
   X2=<N1,
   N is  N1.
maxDigit(X,N):-
   X1 is X//10,
   X2 is X mod 10,
   maxDigit(X1,N1),
   X2>N1,
   N is X2.

Please add a description in your question body of what you are trying to achive. Question title can be improved as well to something like: "Find biggest digit in a number" — Alex, Jun 13 '16 at 00:25
I fixed your question, but I won't be always your back. Next time follow what @Alex said. — peterh, Jun 13 '16 at 02:45

score 2 · Answer 1 · edited May 23 '17 at 12:22

2

Using SICStus Prolog 4.3.3 we simply combine n_base_digits/3 and maximum/2 like so:

?- n_base_digits(12390238464, 10, _Digits), maximum(Max, _Digits).
Max = 9.

edited May 23 '17 at 12:22

Community

1
1

answered Jun 14 '16 at 01:02

repeat

18,496
4
54
166

1

Using `D is 7^7^7 * 10 + 9`, this is *so* slow! – false Jun 14 '16 at 09:52
@false. Actually, it isn't... SICStus is giving me an representation error almost instantly;) – repeat Jun 14 '16 at 21:01
2

So you are not using `clpz`. – false Jun 14 '16 at 21:22

repeat · Answer 2 · 2016-06-24T14:49:45.347

A comment suggested stopping as soon as the maximum digit is encountered. This is how we do:

:- use_module(library(clpfd)).    
:- use_module(library(reif)).

#=(X, Y, T) :- X #= Y #<==> B, bool10_t(B, T).

bool10_t(1, true).
bool10_t(0,false).

Based on if_/3, (;)/3 and (#=)/3 we then define:

n_base_maxdigit(N, Base, D) :-
   N    #>  0,                               % positive integers only
   Base #>  1,                               % smallest base = 2
   D    #>= 0,
   D    #<  Base,
   n_base_maxdigit0_maxdigit(N, Base, 0, D).

n_base_maxdigit0_maxdigit(N, Base, D0, D) :-
   D1 #= N mod Base,
   N0 #= N //  Base,
   D2 #= max(D0,D1),
   if_(( D2 + 1 #= Base ; N0 #= 0 ),
       D = D2,
       n_base_maxdigit0_maxdigit(N0, Base, D2, D)).

Sample query using SWI-Prolog 7.3.22 with Prolog lambda:

?- use_module(library(lambda)).
true.

?- Max+\ ( N is 7^7^7 * 10+9, time(n_base_maxdigit(N,10,Max)) ).
% 663 inferences, 0.001 CPU in 0.001 seconds (100% CPU, 1022162 Lips)
Max = 9.

`?- Max+\ ( N is 7^7^7 * 10+9, time(n_base_maxdigit(N,10,Max)) ).` — false, Jun 23 '16 at 12:16

joel76 · Accepted Answer · 2016-06-15T16:54:18.153

1

You have just to use if/then/else :

maxDigit(X,X):-
   X<10,
   !. % added after false's remark

maxDigit(X,N):-
   X1 is X//10,
   X2 is X mod 10,
   maxDigit(X1,N1),
   (   X2<N1
   ->  N =  N1
   ;   N = X2).

edited Jun 15 '16 at 16:54

answered Jun 13 '16 at 15:38

joel76

5,565
1
18
22

Really elegant. Didn't know about if -> then ; else possibilities. Thanks! – milosponj Jun 13 '16 at 17:06
Thank you. There is a way to click to accept the solution. – joel76 Jun 13 '16 at 18:33
Done. Sorry about that. – milosponj Jun 13 '16 at 22:13
2

`maxDigit(0,1).` loops and `maxDigit(0,X)` produces infinitely many (correct but identical) answers. – false Jun 14 '16 at 09:16
@false : yes, this can be solved by a cut after maxDigit(X1,N1). – joel76 Jun 14 '16 at 16:49
That cut is pretty much misplaced - and you have still two answers for `maxDigit(0,X).` – false Jun 14 '16 at 17:27
Maybe it's displaced but I have only one solution for maxDigit(0,X). – joel76 Jun 15 '16 at 07:46
Oups, I'll change my glasses, sorry. – joel76 Jun 15 '16 at 16:47
Hope it's now fixed ! – joel76 Jun 15 '16 at 16:53

score 0 · Answer 4 · answered Jun 14 '16 at 05:37

0

in SWI-Prolog could be:

maxDigit(N,M) :- number_codes(N,L), max_list(L,T), M is T-0'0.

answered Jun 14 '16 at 05:37

CapelliC

59,646
5
47
90

Alright! How about using `max_member(T,L)` instead of `max_list(L,T)` and adding `:- use_module(library(lists)).` ? That way the same code would run with SWI *and* SICStus. – repeat Jun 14 '16 at 09:52

How to find the biggest digit in a number in Prolog?

4 Answers4