Force batch file to load to RAM before running

Question

I have a batch file in an administrative partition of my portable drive, with a shortcut symlinked to it on the root of the drive. The purpose of the file is to unmount the drive and remount it as the specified letter (mostly for convenience).

When the file is opened, it is opened relative to the current letter rather than to the volume ID, so naturally, when the unmount happens, the command processor has no idea what to do next as it reads the file as needed rather than caching it.

There are two foreseeable solutions that I can think of but can't figure out:

Make the file get cached into RAM before executing
Make the file run relative to the volume ID instead of the mountpoint (tried using {VOLID}\file where {VOLID} is the volume ID, but it couldn't find the file although it was there (navigating to {VOLID}\ correctly opened the directory, but trying to open the file didn't correctly open the file.

score 5 · Accepted Answer · edited May 23 '17 at 10:34

Despite of the other answers, it's trivial to cache a whole batch script to RAM.

You only need to build a single block, as blocks are parsed and cached before they can be executed.

But blocks have some drawbacks, percent expansion doesn't work, therefore you need to use delayed expansion.
call and goto can't be used, as they would try to read from the file again.

(goto) 2>nul & (
  echo The script is started 
  REM Need to change the directory, else the unmount doesn't work
  c:
  mountvol e: /p
  mountvol g: \\?\Volume{VOLID}\
  dir G:\
  echo The script will end now
  REM Here you need the goto 2>nul hack to avoid an error message
)

The (goto) 2>nul & seems strange here, but it's explained at SO:How to make a batch file delete itself?.
It works also without the goto, but then the scripts ends with an error message

score 2 · Answer 2 · edited May 23 '17 at 12:34

2

Have the batch file determine where it is running from see this. If it's running from the portable drive have it make a copy of itself to a permanent drive location (c:\temp for instance) then run that copy of the batch file.

When running a bath file there is no concept of running it from RAM. Windows command processor will always go back to the .bat file for the 'next' command to run. If you edit a batch file while it's running the command processor will pick up your changes.

edited May 23 '17 at 12:34

Community

1
1

answered Jun 21 '16 at 00:16

JJF

2,681
2
18
31

I have tried to avoid that, but will do it if that's required, although, it seems that when I am running the file from windows explorer, the process as well as all child processes get killed when I dismount (doesn't happen from cmd), so the script never completes albeit having the file run from TEMP. – Arthur Uzulin Jun 21 '16 at 00:50

score 1 · Answer 3 · edited May 23 '17 at 10:28

JJF wrote already the correct answer. It is not possible to copy a batch file to RAM and inform Windows command interpreter to interpret the command lines in memory. It would be possible to create a RAM disk, copy the batch file to the RAM disk and run it from there. But this just makes the task more complicated than necessary.

This commented batch code demonstrates how to copy a batch file to directory for temporary files and start it there for complete processing in a separate Windows command process.

@echo off
rem Is the batch file path not the path of directory for temporary files?
if /I not "%~dp0" == "%TEMP%\" (

    rem Copy the batch file to directory for temporary files.
    copy "%~f0" "%TEMP%" >nul
    rem Run the copy in a separate command process with name of the batch
    rem file with extension as window title and exit this batch process.
    start "%~nx0" "%TEMP%\%~nx0"
    goto :EOF
)

echo The batch file is now running from directory for temporary files.
echo.
pause

rem Delete the batch file in directory for temporary files
rem and exit the command process started for this batch file.
del "%TEMP%\%~nx0" & exit

Replace the two echo commands and the pause command by your batch code.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

call /? ... explains %~dp0 (drive and path of argument 0 which is the batch file itself) and %~nx0 (name and extension of batch file)
copy /?
del /?
echo /?
exit /?
goto /?
if /?
pause /?
rem /?
start /?

See also answer on Single line with multiple commands using Windows batch file for an explanation of operator & used here two run the two commands del and exit read from one line to avoid an opened console window with an error message as batch file deleted unexpected for the Windows command interpreter while processing it.

Force batch file to load to RAM before running

3 Answers3

Linked