perlre match capturing group multiple times on the same line

Question

Given the following line;

<tag id='1'><![CDATA[this is a string of text]]><tag id='2'><![CDATA[this is another string of text]]><tag id='3'><![CDATA[this is the last string of text]]>

I'm trying to match the text string inside the CDATA square brackets in a way that returns every match without having to split the line first. I can accomplish this by splitting the line (see below) but am trying to better understand perl regex matching and whether I can accomplish the same using regex.

my $string = qq(<tag id='1'><![CDATA[this is a string of text]]><tag id='2'><![CDATA[this is another string of text]]><tag id='3'><![CDATA[this is the last string of text]]>)
my @splitline = split(/\</, $string);
foreach(@splitline){
   if ($_ =~ /\!\[CDATA\[(.*?)\]\]/){
      print "$1\n";
   }
}

The result of above is

this is a string of text

this is another string of text

this is the last string of text

If I try this, it only returns the first match.

my $string = qq(<tag id='1'><![CDATA[this is a string of text]]><tag id='2'><![CDATA[this is another string of text]]><tag id='3'><![CDATA[this is the last string of text]]>)
if ($string =~ /\!\[CDATA\[(.*?)\]\]/){
   print "$1\n";
}

changing my regex to the following returns no data

$string =~ /\!\[CDATA\[(.*?)+\]\]/g

Possible duplicate of [How to match multiple occurrences of string within a string using reg ex](http://stackoverflow.com/questions/7041308/how-to-match-multiple-occurrences-of-string-within-a-string-using-reg-ex) — TemporalWolf, Jun 30 '16 at 20:13
just use the global modifier to look past the first occurance. `\!\[CDATA\[(.*?)\]\]/g` — Chris Doyle, Jun 30 '16 at 20:25
thanks for the comments. toolic - this is a small part of a script where i just need to grab the string text and have no use for the other xml data so i'm trying to avoid an xml parser. @TemporalWolf - added detail, i think my question is slightly different. ChrisDoyle - see my edited post, this does not work but i'm not sure why. — Matt M, Jun 30 '16 at 20:36

score 2 · Accepted Answer · answered Jun 30 '16 at 20:37

The issue is you are calling the match in scalar context (I.E with the if statement). Instead you should call it in list context and load all the matches into an array. then you can check the array after and print the results.

my $string = qq(<tag id='1'><![CDATA[this is a string of text]]><tag id='2'><![CDATA[this is another string of text]]><tag id='3'><![CDATA[this is the last string of text]]>);

my @matches = $string =~ /\!\[CDATA\[(.*?)\]\]/g;

print join("\n",@matches) if @matches;

OUTPUT

this is a string of text
this is another string of text
this is the last string of text

if you really want to call it in scalar context then you will need to iterate ver all the matches as the perl documentation states that in scalar contect it will track the position of each match.

my $string = qq(<tag id='1'><![CDATA[this is a string of text]]><tag id='2'><![CDATA[this is another string of text]]><tag id='3'><![CDATA[this is the last string of text]]>);

while ($string =~ /\!\[CDATA\[(.*?)\]\]/g){
    print "$1\n";
}

score 2 · Answer 2 · answered Jun 30 '16 at 20:39

2

Use the "repeated matching" capability in Perl, while(.../g...:

Change

if ($string =~ /\!\[CDATA\[(.*?)\]\]/){

to

while ($string =~ /\!\[CDATA\[(.*?)\]\]/g){

answered Jun 30 '16 at 20:39

Jeff Y

2,437
1
11
18

perlre match capturing group multiple times on the same line

2 Answers2