renaming .jpg files in a folder using batch file

Question

I have a folder that has bmp files , they may be 4 in a folder or 50 in a folder, but they are

image.bmp
image1.bmp
image2.bmp

I started a batch file with the below code:

@echo off
setlocal enableDelayedExpansion
SET counter=0
SET /P filename=Please enter the filename:
for %%G in (C:\Test_Folder) do (
  ren image*.bmp "%filename%""%counter%".bmp
  SET /A counter=%counter%+1;
  echo "%counter%"
)
pause

but the counter does not increment, can some one give some light to my code?

you have a [delayed expansion problem](http://stackoverflow.com/a/30284028/2152082) — Stephan, Jul 05 '16 at 15:42
`gci image*.bmp | rename -newname { $_ -replace "image", "picture " }`, in PowerShell. No need for batch files, it's $currentyear. — TessellatingHeckler, Jul 05 '16 at 15:58
I corrected it , and the counter does move to the next number. But I cannot get the loop to work to rename the rest of the files :( — user396123, Jul 05 '16 at 16:07
`ren image*.bmp "%filename%!counter!.bmp"` ? All of them to the same name, trying it [n] times? Won't work. Logical failure. — Stephan, Jul 05 '16 at 16:14

Stephan · Answer 1 · 2016-07-05T16:37:29.057

@echo off
setlocal enableDelayedExpansion
SET counter=0
SET /P filename=Please enter the filename:
for %%G in (C:\Test_Folder\image*.bmp) do (
  ren "%%~G" "%filename%!counter!.bmp"
  SET /A counter+=1
  echo "!counter!"
)
pause

Changes:
using delayed expansion for the counter variable.
forprocesses matching files in the folder instead of the folder itself.
use ren to rename single files instead of wildcard usage.
SET /A counter+=1 instead of SET /A counter=!counter!+1 (does the same, but improved readabilty).

renaming .jpg files in a folder using batch file

1 Answers1