Vim Markdown Folding?

Question

I just realized that VIM 7.3 has built-in support for highlighting Markdown files. Excellent. However, it doesn't fold on the headings.

Can any offer suggestions on how to get this working?

Alternatively, I'm using Markdown only as a way to get simple structured text. If there is a better alternative format, please also suggest. But not sure I dig TVO or VimOutliner.

This Vimcast just aired this week. http://vimcasts.org/episodes/writing-a-custom-fold-expression/ — Michael Berkowski, Nov 27 '12 at 15:18
Vim natively supports this now: https://stackoverflow.com/a/45532557/5120089 — yukashima huksay, Apr 16 '20 at 09:52

Jeromy Anglim · Answer 1 · 2011-01-24T10:57:37.713

37

When I use markdown I only use the hash-style headings with space separating hashes and text. This makes the folding task a lot simpler.

I'm pretty new to Vim, so use the following at your own risk. I added the following code to my vimrc and it folds headings based on number of hashes, and it retains the syntax colouring.

function! MarkdownLevel()
    if getline(v:lnum) =~ '^# .*$'
        return ">1"
    endif
    if getline(v:lnum) =~ '^## .*$'
        return ">2"
    endif
    if getline(v:lnum) =~ '^### .*$'
        return ">3"
    endif
    if getline(v:lnum) =~ '^#### .*$'
        return ">4"
    endif
    if getline(v:lnum) =~ '^##### .*$'
        return ">5"
    endif
    if getline(v:lnum) =~ '^###### .*$'
        return ">6"
    endif
    return "=" 
endfunction
au BufEnter *.md setlocal foldexpr=MarkdownLevel()  
au BufEnter *.md setlocal foldmethod=expr

edited Jan 24 '11 at 10:57

answered Jan 13 '11 at 06:36

Jeromy Anglim

33,939
30
115
173

32

You can simplify the MarkdownLevel function to just `function MarkdownLevel() let h = matchstr(getline(v:lnum), '^#\+') if empty(h) return "=" else return ">" . len(h) endif endfunction`, which I post smooshed into one line because this is a comment. – Omar Antolín-Camarena Aug 29 '12 at 16:06
the op solution works for me but the shorted solution in comments doesn't work for me. – yukashima huksay Jul 11 '19 at 06:48
With what key or command is the folding supposed be performed? – theerrormagnet Jun 13 '22 at 05:55

score 28 · Answer 2 · edited Mar 23 '23 at 23:05

let g:markdown_folding = 1

You can enable markdown folding feature by adding this in your .vimrc if you are using the latest version of Vim - no need to be the latest, but I don't know the exact version.

For some reason it's not documented in the README but you can find the related code in the repository.

FYI, if you don't want the sections closed when you open a file, refer to this SO thread. I think adding this would be the best way but you may have a different preference.

set nofoldenable

Update

Unfortunately, I stopped using markdown_folding since it makes things slow (Github issue).

I'm not sure why this isn't upvoted more - it works perfectly for me. — jobu1342, Mar 25 '21 at 20:50

score 7 · Answer 3 · answered Oct 01 '10 at 19:42

Here is a try at a recursive header folding rule. It doesn't include the underline style of Markdown header, but I'm guessing those would be awkward for your purposes anyway.

Put the following code into your .vimrc:

au FileType markdown syn region myMkdHeaderFold
        \ start="\v^\s*\z(\#{1,6})"
        \ skip="\v(\n\s*\z1\#)\@="
        \ end="\v\n(\s*\#)\@="ms=s-1,me=s-1
        \ fold contains=myMkdHeaderFold

au FileType markdown syn sync fromstart
au FileType markdown set foldmethod=syntax

score 7 · Accepted Answer · answered Oct 07 '10 at 03:24

7

I had the same question, and played around with Jander's nice solution. The only problem is that by defining folding using syntax, you lose any Markdown syntax highlighting.

Given that you might be interested in alternate markups, I would suggest using reStructuredText, and the amazing Vst vim extension. It does folding very nicely. Rst is much more powerful than Markdown.

answered Oct 07 '10 at 03:24

ematsen

134
2

I ended up using Viki instead. It's not Markdown, but it does folding properly. – Muchin Oct 08 '10 at 04:59
I suppose the nice thing about Rst is that it can then be used for many other purposes, such as a Jekyll wiki, HTML, LaTex.. – ematsen Oct 08 '10 at 14:27
Work arounds are no longer needed. See Sanghyun's answer below about the built in vimrc flag. – Lomky Sep 24 '19 at 18:46

score 7 · Answer 5 · answered Mar 23 '12 at 21:37

There is a vim-markdown plugin at https://github.com/plasticboy/vim-markdown .

The code related to folding from there appears to be:

" fold region for headings
syn region mkdHeaderFold
    \ start="^\s*\z(#\+\)"
    \ skip="^\s*\z1#\+"
    \ end="^\(\s*#\)\@="
    \ fold contains=TOP

" fold region for lists
syn region mkdListFold
    \ start="^\z(\s*\)\*\z(\s*\)"
    \ skip="^\z1 \z2\s*[^#]"
    \ end="^\(.\)\@="
    \ fold contains=TOP

syn sync fromstart
setlocal foldmethod=syntax