WebBrowser load and display URLs from file

Question

I want to load a list of URLs in a text file. I have done that using a For Each loop, but I want the browser to load the page first fully before going to the next URL. Here is my code:

For Each url in File.ReadAllLines("urls.txt")
    Browser.Navigate(url)
Next

It doesn't display anything. I tried using:

Do While Browser.ReadyState <> WebBrowserReadyState.Complete
    Application.DoEvents()
Loop

It displays the page but the first line is the only one being loaded.

hey @Gerard Balaoro, will they need to be opened in another WB tabbed window or just load and then go to the next URL? — user1234433222, Aug 21 '16 at 13:57
what do you think about telling it to wait 5 seconds until looping again? — user1234433222, Aug 21 '16 at 14:10
@Werdna Its my temporary solution. But the net speed varies and it depends on the site. I need it to adjust automatically — Gerard Balaoro, Aug 21 '16 at 14:15
have a look @ Visual Vincent's answer for you, here is a link its in c# but it have some good examples of waiting for a task to complete :) http://stackoverflow.com/questions/15149811/how-to-wait-for-async-method-to-complete — user1234433222, Aug 21 '16 at 14:16
@VisualVincent : Not at all my friend hahahahahah, In fact, I think your answer is great for it simplicity. — user1234433222, Aug 21 '16 at 14:22
@Werdna : Good, because I didn't see your comments until after I had written the first version. Though I did copy you a little by explaining how to add a delay. — Visual Vincent, Aug 21 '16 at 14:25

Visual Vincent · Accepted Answer · 2016-08-21T14:28:42.407

If you want to navigate to each URL after the other you are better of storing all of them in a class level array and subscribing to the WebBrowser.DocumentCompleted event, then keep track of which URL index you're currently at via a class level Integer variable.

When the DocumentCompleted event is raised you just increment the integer variable and load the URL from the next item of the array.

Public Class Form1
    Dim URLs As String()
    Dim UrlIndex As Integer = 0

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        URLs = File.ReadAllLines("urls.txt")
        WebBrowser1.Navigate(URLs(UrlIndex))
    End Sub

    Private Sub WebBrowser1_DocumentCompleted(sender As System.Object, e As System.Windows.Forms.WebBrowserDocumentCompletedEventArgs) Handles WebBrowser1.DocumentCompleted
        UrlIndex += 1
        If UrlIndex >= URLs.Length Then
            UrlIndex = 0 'Go back to the beginning.
        End If

        WebBrowser1.Navigate(URLs(UrlIndex))
    End Sub
End Class

To add a delay to it to make each URL show for a little while you can use a Timer (Credit to Werdna for bringing up the subject):

Private Sub WebBrowser1_DocumentCompleted(sender As System.Object, e As System.Windows.Forms.WebBrowserDocumentCompletedEventArgs) Handles WebBrowser1.DocumentCompleted
    Timer1.Start()
End Sub

Private Sub Timer1_Tick(sender As System.Object, e As System.EventArgs) Handles Timer1.Tick
    UrlIndex += 1
    If UrlIndex >= URLs.Length Then
        UrlIndex = 0 'Go back to the beginning.
    End If

    WebBrowser1.Navigate(URLs(UrlIndex))
    Timer1.Stop()
End Sub

Just set the timer's Interval property to change how long a site should be displayed (in milliseconds).

WebBrowser load and display URLs from file

1 Answers1