Get a list of all the files in a directory (recursive)

Question

I'm trying to get (not print, that's easy) the list of files in a directory and its sub directories.

I've tried:

def folder = "C:\\DevEnv\\Projects\\Generic";
def baseDir = new File(folder);
files = baseDir.listFiles();

I only get the directories. I've also tried:

def files = [];

def processFileClosure = {
        println "working on ${it.canonicalPath}: "
        files.add (it.canonicalPath);
    }

baseDir.eachFileRecurse(FileType.FILES, processFileClosure);

But "files" is not recognized in the scope of the closure.

How do I get the list?

score 244 · Accepted Answer · answered Oct 17 '10 at 18:30

244

This code works for me:

import groovy.io.FileType

def list = []

def dir = new File("path_to_parent_dir")
dir.eachFileRecurse (FileType.FILES) { file ->
  list << file
}

Afterwards the list variable contains all files (java.io.File) of the given directory and its subdirectories:

list.each {
  println it.path
}

answered Oct 17 '10 at 18:30

Christoph Metzendorf

7,968
2
31
28

17

By default, groovy imports java.io but not groovy.io so to use FileType you must have explicitly import it. – Chris Mountford Jun 28 '13 at 07:04
4

For using FileType, make sure you use the right groovy version: "the class groovy.io.FileType was introduced in Groovy version 1.7.1." see: http://stackoverflow.com/questions/6317373/unable-to-resolve-class-groovy-io-filetype-error – Tidhar Klein Orbach Sep 29 '14 at 12:36
This was displaying the folder names along with its path. Eg: `/tmp/directory1` How to get the `directory1` alone in the output – soundararajan.c Mar 12 '17 at 04:50
weird..this gives the root path even if i preface it with a `.` It goes `/./path` – light24bulbs Jul 23 '18 at 15:05
How can I list all folders on directory ? – Carlos Andres Aug 07 '18 at 13:57
does `file -> list << file` works similar to `list.add(it)` or is there a difference? – R. Sluiter Mar 09 '20 at 14:22
@R.Sluiter there is no difference – Christoph Metzendorf Mar 09 '20 at 17:21
This solved my problem: https://stackoverflow.com/questions/41934110/how-to-get-files-in-jenkins-pipeline-file by placing the code in the `script` section of a shared library. – dan Oct 06 '20 at 20:23
1

there is no type File in jenkins goovy – Verthais Feb 28 '22 at 09:19

score 29 · Answer 2 · answered Jul 22 '16 at 12:18

Newer versions of Groovy (1.7.2+) offer a JDK extension to more easily traverse over files in a directory, for example:

import static groovy.io.FileType.FILES
def dir = new File(".");
def files = [];
dir.traverse(type: FILES, maxDepth: 0) { files.add(it) };

See also [1] for more examples.

[1] http://mrhaki.blogspot.nl/2010/04/groovy-goodness-traversing-directory.html

score 6 · Answer 3 · edited Jul 05 '18 at 21:41

6

The following works for me in Gradle / Groovy for build.gradle for an Android project, without having to import groovy.io.FileType (NOTE: Does not recurse subdirectories, but when I found this solution I no longer cared about recursion, so you may not either):

FileCollection proGuardFileCollection = files { file('./proguard').listFiles() }
proGuardFileCollection.each {
    println "Proguard file located and processed: " + it
}

edited Jul 05 '18 at 21:41

Peter Mortensen

30,738
21
105
131

answered Apr 28 '16 at 18:11

ChrisPrime

458
1
6
13

1

although this probably does not recurse through subdirectories. However: worked for my purposes for separating out proguard files and importing them all at once :) – ChrisPrime Apr 28 '16 at 18:12
Unfortunately this does not answer the question "all the files in a directory (recursive)". It will only list the current directory and is misleading in the context. – ottago Jun 04 '16 at 06:28
`fileTree` recurses. – Noel Yap Aug 24 '17 at 16:56
`FileTree` does not include directories (not treating them as files). – DNax Dec 21 '17 at 15:39

score 3 · Answer 4 · answered Mar 19 '20 at 21:05

This is what I came up with for a gradle build script:

task doLast {
    ext.FindFile = { list, curPath ->
        def files = file(curPath).listFiles().sort()

        files.each {  File file ->

            if (file.isFile()) {
                list << file
            }
            else {
                list << file  // If you want the directories in the list

                list = FindFile( list, file.path) 
            }
        }
        return list
    }

    def list = []
    def theFile = FindFile(list, "${project.projectDir}")

    list.each {
        println it.path
    }
}

Using the list was taken from the IDEA above. The problem with the above scripts is that they require to import groovy.io.FileType.FILES. gradle scripts don't like that. So I just made a method to look for the files that calls itself when a directory is found. — Timothy Strunk, Mar 19 '20 at 21:07

score 2 · Answer 5 · answered Oct 16 '22 at 09:20

2

With Kotlin Gradle script one can do it like this:

// ...
val yamls = layout.files({
    file("src/main/resources/mixcr_presets").walk()
        .filter { it.extension == "yaml" }
        .toList()
})
// ...

answered Oct 16 '22 at 09:20

dbolotin

390
3
12

Get a list of all the files in a directory (recursive)

5 Answers5

Linked