How to instantiate different frame types?

Question

I'm here again with frames. I've this main form:

It's only a simple form created in order to understand the use of frames. With the two buttons on the top of the form I would like to open this two frames:

Frame1

and Frame2

here is the code the simple code of the first frame:

unit AppFrame1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.StdCtrls;

type
  TFrame1 = class(TFrame)
    lblFrame1: TLabel;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

end.

and here is the code of the second frame:

unit AppFrame2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.StdCtrls;

type
  TFrame2 = class(TFrame)
    lblFrame2: TLabel;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

end.

So nothing special in the two frames. in order to open the frames from the main form I've created an interface like this:

unit FramesManager;

interface

uses
  Vcl.Forms, Vcl.StdCtrls, Vcl.ExtCtrls, Vcl.Controls;

type

  TFrameClass = class(TFrame)

  end;


  IFrameManager = interface
  ['{A00E0D1B-3438-4DC4-9794-702E8302B567}']
    procedure CreateGenericFrame(AParentPanel: TPanel; AFrameClass: TFrameClass);
    procedure DestroyGenericFrame();
  end;

  TFrameManager = class(TInterfacedObject, IFrameManager)
  private
    FGenericFrame: TFrameClass;
    procedure CreateGenericFrame(AParentPanel: TPanel; AFrameClass: TFrameClass);
    procedure DestroyGenericFrame();
  public
    property Frame: TFrameClass read FGenericFrame write FGenericFrame;
  end;

implementation

{ TFrameManagement }

procedure TFrameManager.CreateGenericFrame(AParentPanel: TPanel;
  AFrameClass: TFrameClass);
begin
  FGenericFrame := AFrameClass.Create(AParentPanel);
  FGenericFrame.Parent := AParentPanel;
  FGenericFrame.Align := alClient;
end;

procedure TFrameManager.DestroyGenericFrame;
begin
  FGenericFrame.Free;
end;

end.

At this point my intension is to use the interface for create the two frames but I can't realize how to reach this task. My main form code is this:

unit Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.ExtCtrls, FramesManager, Vcl.StdCtrls, AppFrame1, AppFrame2;

type
  TfrmMain = class(TForm)
    pnlCommands: TPanel;
    pnlFrames: TPanel;
    btnCrtFrame1: TButton;
    btnCrtFrame2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure btnCrtFrame1Click(Sender: TObject);
    procedure btnCrtFrame2Click(Sender: TObject);
  private
    FFrame: IFrameManager;
  public
    { Public declarations }
  end;

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}


procedure TfrmMain.FormCreate(Sender: TObject);
begin
  FFrame := TFrameManager.Create;
end;


procedure TfrmMain.btnCrtFrame1Click(Sender: TObject);
begin
  FFrame.CreateGenericFrame(pnlFrames, TFrame1);
end;

procedure TfrmMain.btnCrtFrame2Click(Sender: TObject);
begin
  FFrame.CreateGenericFrame(pnlFrames, TFrame2);
end;

end.

When I try co compile the project I receive this errors:

[dcc32 Error] Main.pas(41): E2010 Incompatible types: 'TFrameClass' and 'class of TFrame1'
[dcc32 Error] Main.pas(46): E2010 Incompatible types: 'TFrameClass' and 'class of TFrame2'

So I would like to understand how to create the two frames from the main. How can I assign the right object type to the TFrameClass? I've tought about generics, but I have not idea on how to implement this kind of interface in order to open a "generic" frame that can be created form the main when the use choose to open it.

I hope I have explained clearly my problem, but I know that it may seem complicate to understand.

NGLN · Accepted Answer · 2016-09-28T10:30:16.130

5

type
    TFrameClass = class(TFrame)
    end;

Your TFrameClass declaration is wrong. Right now it is declared as a descendant of TFrame which is just another class.

What you need is a class reference:

type
  TFrameClass = class of TFrame;

Because both TFrame1 and TFrame2 descend from TFrame, both can be put into a TFrameClass variable.

But I am pretty sure this TFrameClass already exists somewhere in the VCL in which case you do not have to redeclare this type.

Subsequently, the type of FGenericFrame private field needs to become TFrame instead of TFrameClass.

(Also, this has nothing to do with Generics.)

edited Sep 28 '16 at 10:30

answered Sep 28 '16 at 09:33

NGLN

43,011
8
105
200

Hi NGLN, I've already try to set the TFrameClass as you say but in this case I receive this error: E2010 Incompatible types: 'TFrameClass' and 'TFrame' – Eros Sep 28 '16 at 09:43
@Eros NGLN is addressing the question that you asked. If you want to instead as about some other code, you would need to do that. You can't expect us to debug code that you did not show us. Remember that we are not a debugging service. You still need to be prepared to make some effort. – David Heffernan Sep 28 '16 at 09:53
Hi David, you're right but I've tryed many things so I've not posted the last code. I've edited the FramesManager code and now it's the one I've in my project. – Eros Sep 28 '16 at 10:03
Eros, regarding your first comment, see my edit: the `FGenericFrame` private field need to become a `TFrame` instead of `TFrameClass`. – NGLN Sep 28 '16 at 10:28
Classic mistake. Asker tries 25 things, trial and error, code getting more and more messed up, then asks with the final messed up version. Step back and think a little. – David Heffernan Sep 28 '16 at 10:41
Thanks NGLN, I forgot to change it. Now it work correctly – Eros Sep 28 '16 at 11:37
4

@Eros If it works, you should do NGLN a favor and accept his answer. – René Hoffmann Sep 28 '16 at 12:02

How to instantiate different frame types?

1 Answers1