Clojure Atoms, I want to return the final value

Question

Ok so put into my function an array an I keep so do some stuff to return a hashmap with a string as key and a list as value. I want to get only the final value and pass it as a parameter to another function.

Below is a java code which i am trying to translate into clojure

contents = documentContent.split("[ ,\\.]+");
        for(int i = 0; i < contents.length; i++) {
            String word = contents[i];
            if(index.containsKey(word)) {
                index.get(word).add(i);
            } else {
                List<Integer> list = new ArrayList<>();
                list.add(i);
                index.put(word, list);
            }
        }

Clojure code so far it somewhat works but i cant return the final value and pass it to another function

(defn indexFinder [contents] 
  (let [mem (def xs (atom {}))]
    (map-indexed
      (fn [index element]
        (if (contains? @xs element)
          (swap! xs assoc element (conj (@xs element) index))
          (swap! xs assoc element [index])))
      contents)))

don't use def inside of a let like that. or inside of a function either really. — Brandon Henry, Oct 09 '16 at 02:14

score 2 · Answer 1 · answered Oct 09 '16 at 11:00

2

Here is how I would write it:

(defn index-finder [s]
  (->> (clojure.string/split s #"[ ,\\.]+")
       (map-indexed list)
       (reduce (fn [acc [i w]]
                 (update acc w conj i)) {})))

Example use:

(index-finder "aaa bbb ccc ddd aaa bbb") ;; {"aaa" (4 0), "bbb" (5 1), "ccc" (2), "ddd" (3)}

Note: when starting learning Clojure, one tends to think that he needs atoms way to often.

answered Oct 09 '16 at 11:00

nha

17,623
13
87
133

hello nha, your codes seems to do what i want but im having a hard time undrstanding. what is the purpose of the list in the map indexed – user3602477 Oct 17 '16 at 16:18
also @nha how is the vector being worked on after the sentence is split – user3602477 Oct 17 '16 at 16:20
@user3602477 play with the individual functions to understand them, look for docs on map-indexed, reduce, update, conj... For instance try `(map-indexed list ["a" "b" "c" "d"])` `(conj nil 1)` `(conj '(1) 2)`. There are lots of examples on clojure docs, for instance for update: https://clojuredocs.org/clojure.core/update – nha Oct 17 '16 at 18:51
i do undsertand the functions but I am new to clojure so bear with me. just want to know what the list contains. because after we split the sentence s is assigned to the vector but I dont see s being used again – user3602477 Oct 17 '16 at 19:03
@user3602477 then try the following: `(defn index-finder [s] (->> (clojure.string/split s #"[ ,\\.]+") (map-indexed list)))` you will see what the result is (I guess this is the list you are talking about). – nha Oct 17 '16 at 20:01
ok so every iteration is translated into a list. @nha what does this symbol "->>" do in the codes also – user3602477 Oct 17 '16 at 20:37
the thing is I also need to hold that vector after the so i can pass it to another function – user3602477 Oct 17 '16 at 20:39
@user3602477 "->>" is the thread-last macro https://clojuredocs.org/clojure.core/-%3E%3E . Which vector are you talking about? If you need an intermediate result somewhere else, split your function (as in every other language in fact). – nha Oct 17 '16 at 21:58
nha thank you so much fro your replies i ended up using @Brandons H answer – user3602477 Oct 17 '16 at 23:09

score 1 · Accepted Answer · answered Oct 09 '16 at 02:08

I'd recommend against the atom in the first place.

(->> (zipmap (range) contents) ;contents is a list of words
     (reduce (fn [index [location word]]
               (merge-with concat index {word (list location)})) {}))

example:

user=> (def contents (clojure.string/split "hello there these are some words and some repeated words" #" "))
#'user/contents
user=> contents
["hello" "there" "these" "are" "some" "words" "and" "some" "repeated" "words"]

user=>     (->> (zipmap (range) contents)
  #_=>          (reduce (fn [index [location word]]
  #_=>                    (merge-with concat index {word (list location)})) {}))
{"hello" (0), "some" (7 4), "there" (1), "and" (6), "are" (3), "these" (2), "words" (9 5), "repeated" (8)}

Doesn't this have problems with large sequences? See https://stuartsierra.com/2015/04/26/clojure-donts-concat and http://stackoverflow.com/questions/24958907/why-does-reduce-give-a-stackoverflowerror-in-clojure (basically using reduce and concat seems dangerous (knowing that merge-with uses reduce)) — nha, Oct 21 '16 at 11:23

score 1 · Answer 3 · answered Oct 09 '16 at 03:30

The original indexFinder is missing a doall to force its side effects (to update the atom). And also declaration of mem is not required. With that, a working version may look like this:

(defn indexFinder [contents] 
  (let [xs (atom {})]
    (doall (map-indexed
            (fn [index element]
              (if (contains? @xs element)
                (swap! xs assoc element (conj (@xs element) index))
                (swap! xs assoc element [index])))
            contents))
    @xs))

You can also simplify the map-indexed part:

(defn indexFinder [contents] 
  (let [xs (atom {})]
    (doall (map-indexed
            (fn [i e] (swap! xs update e conj i))
            contents))
    @xs))

Or if you don't want to rely on side effects, you can use this instead (similar to Brandon's answer but use group-by):

(defn index-finder [contents]
  (->> (zipmap (range) contents)
       (group-by last)
       (fmap (partial map first))))

where fmap is used to map a function over values (see algo.generic):

(defn fmap [f m]
  (into (empty m) (for [[k v] m] [k (f v)])))

Clojure Atoms, I want to return the final value

3 Answers3