Validate the date given by user using batch file

Question

Using a batch file, I am taking the date from user. Now, I want to validate if the date in YYYY-MM-DD format.

I have been searching but I am not getting some of the things here: Found this one somewhere:

set /p startDate=Start Date [YYYY-MM-DD]: 
if "%startDate:~2,1%%startDate:~5,1%" neq "--" goto invalidDate
for /f "tokens=2 delims==" %%I in ("%startDate%") do set datetime=%%I
ver > NUL
set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4
if errorlevel 1 goto invalidDate
if not defined dpm[%month%] goto invalidDate
if %leap% equ 0 set dpm[2]=29
if %day% gtr !dpm[%month%]! goto invalidDate
if %day% lss 1 goto invalidDate
echo Date correct: %YYYY%-%MM%-%DD%

What are these: ~2, 1%%variable:~5, %%, In cmd help I found single % but not double %%

Also,

set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4

What is this actually doing. Can anyone explain character by character, please?

Answer 1

Double % are sometimes used (eventhough I do not know the exact purpose; I think it is for a delayed expansion though) but in your case it is just the connection of two variables used:

set foo=foo
set bar=bar
echo %foo%%bar%

-> foobar

Another use of it (at least in batch files) is the declaration and usage of variables in for loops: for /l %%I in(1,1,5) do echo %%i. In the command prompt you would only write %i.
The second line you posted makes no sense to me to be honest... Thanks to Aacinis comment this makes sense to me now! What basically gets done is:

Variables are set with an /Arithmetic term where a 1 is added in front to subtract it back again. Example:

set /a year=1%YYYY%-10000

-> Set the value of the variable year to the value of the variable 1YYYY - 10000. This is done (thanks to Aacini for the explanation again) to prevent the input with a leading zero (e.g. 08) to get interpreted as an octal value which in this case would lead to an invalid date. Notice that there is a difference if you use /a or not:

set foo=1+1
set /a bar=1+1
echo foo %foo%
echo bar %bar%

Next we have another case of %% which in this case is the modulo operator.

The modulo operator will return the rest of a division if you will. Examples:

10 %% 2 = 0 (You can divide 10 by 2 without any rest)
11 %% 4 = 3 (as 8 by 4 is 2 and the rest from 8 to 11 is 3)

I the variable leap is saved whether the year is a leap year (value == 0) or not (value != 0). However this is somewhat taken easy with the other rules you have to think of when checking for leap years but that does not belong here...

%startDate:~2,1%%startDate:~5,1%

Will produce a string that takes the 1 character after the first 2 and the 1 after the first 5 characters. In your case you would have to change that to ~4,1 and ~7,1 as the 5th and 8th character are the dashes the program checkes for.

J.Baoby suggested this link to have a closer look to. Two other great sources for help about are Dostips and SS64.

Feel free to ask questions :)

Answer 2

You definitely have some code issues with your program but I am going to offer you an alternative to checking for valid dates that uses a little XCOPY trickery. It basically uses XCOPY to check two empty folders for the purpose of copying but we use the /L option so that it will not actually copy anything. The other trick is that if the date is invalid it throws and error before even attempting to copy which we can use to redirect back to the question to ask for a valid date.

@echo off

:invalidDate
cls
set /p startDate=Start Date YYYY-MM-DD:

REM xcopy needs date in m-d-y format
for /f "tokens=1,2,3 delims=-" %%G in ("%startDate%") do set checkdate=%%H-%%I-%%G
set rand=%random%
md "dummy%rand%\empty%rand%"

xcopy /d:%checkdate% /t "dummy%rand%\empty%rand%" "dummy%rand%" >nul 2>&1 ||(
    rd /s /q "dummy%rand%" 
    goto invalidDate
    )

rd /s /q "dummy%rand%"
echo %startdate% is a valid date

pause

Answer 3

Well, if you take a working code, modify it and then you ask "Why this code not works?", I think the answer is obvious...

This is the original code you "found somewhere":

@echo off
setlocal EnableDelayedExpansion

set i=0
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do (
   set /A i+=1
   set dpm[!i!]=%%a
)

set /P "inDate=Please insert date (MM-DD-YYYY format): "
if "%inDate:~2,1%%inDate:~5,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%inDate%") do set "MM=%%a" & set "DD=%%b" & set "YYYY=%%c"
ver > NUL
set /A month=1%MM%-100, day=1%DD%-100, year=1%YYYY%-10000, leap=year%%4  2>NUL
if errorlevel 1 goto invalidDate
if not defined dpm[%month%] goto invalidDate
if %leap% equ 0 set dpm[2]=29
if %day% gtr !dpm[%month%]! goto invalidDate
if %day% lss 1 goto invalidDate
echo Date correct: %YYYY%-%MM%-%DD%
goto :EOF

:invalidDate
echo Bad date

If you want to change the original MM-DD-YYYY date format to YYYY-MM-DD, then you must change these lines:

set /P "inDate=Please insert date (MM-DD-YYYY format): "
if "%inDate:~2,1%%inDate:~5,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%inDate%") do set "MM=%%a" & set "DD=%%b" & set "YYYY=%%c"

... by these ones:

set /P "startDate=Start Date [YYYY-MM-DD]: "
if "%startDate:~4,1%%startDate:~7,1%" neq "--" goto invalidDate
for /F "tokens=1-3 delims=-" %%a in ("%startDate%") do set "YYYY=%%a" & set "MM=%%b" & set "DD=%%c"

A further explanation of !dpm[%month%]! part is given at this answer. I invite you to read such an answer and upvote it, because it just needs a few upvotes to reach 100! ;)