Multiplication in Brainf*ck

Question

I tried to write a brainfuck program which asks the user for two numbers (smaller than 10) to calculate the product of these numbers. After the calculation, it should print the result. My code looks like this:

    ++++[>++++[>+++<-]<-]   writing 48 / 0x30 / '0' in cell(2)
    ,>,>                    reading two numbers in cell(0) and cell(1)
    [<-<->>-]               decrementing cell(0) and cell(1) by 48 / 0x30 / '0'
    <<                      go to cell(0)
    [                       muliplication loop
        >                   go to cell(1)
        [>+>+<<-]           move cell(1) to cell(2) and cell(3)
        >>                  go to cell(3)
        [<<+>>-]            move cell(3) back to cell(1)
        <<<-                decrement cell(0)
    ]
    ++++[>++++[>+++<-]<-]   adding 48 / 0x30 / '0' to cell(2)
    >>.                     print result

This gives me really strange results:

0 * 1 = 3
1 * 1 = 4
1 * 2 = 8
2 * 1 = 5
2 * 2 = :

and so on.

Of course, the output actually looks like this:

1
1
4

but I wanted to show it more readable here.

score 1 · Accepted Answer · answered Dec 07 '16 at 08:17

After some consideration, I realized that I made a huge misstake when I modify the result to a printable number. I use cell(1)as a temporary counter cell, though it still has value in it. So I inserted >[-]< before adding 48 / 0x30 / '0' to the result:

    ++++[>++++[>+++<-]<-]   writing 48 / 0x30 / '0' in cell(2)
    ,>,>                    reading two numbers in cell(0) and cell(1)
    [<-<->>-]               decrementing cell(0) and cell(1) by 48 / 0x30 / '0'
    <<                      go to cell(0)
    [                       mulitplication loop
        >                   go to cell(1)
        [>+>+<<-]           move cell(1) to cell(2) and cell(3)
        >>                  go to cell(3)
        [<<+>>-]            move cell(3) back to cell(1)
        <<<-                decrement cell(0)
    ]
    >[-]<                   set cell(1) to 0 so that it can be used as counter
    ++++[>++++[>+++<-]<-]   adding 48 / 0x30 / '0' to cell(2)
    >>.                     print result

note, that it still only works correctly with results smaller than 10

score 1 · Answer 2 · edited May 23 '17 at 12:30

A really great resource is the Esolangs page on Brainfuck algorithms. There, multiplication is defined as:

temp0[-]
temp1[-]
x[temp1+x-]
temp1[
 y[x+temp0+y-]temp0[y+temp0-]
temp1-]

So, if the tape looked generally like temp0 temp1 x y, with the pointer at temp0, then the resulting substitution would be:

[-]
>[-]
>[<+>-]
<[
 >>[<+<<+>>>-]<<<[>>>+<<<-]
>-]

However, your main problem occurs when calling . to output. Your method only works when outputting single digit numbers. To output the contents of a cell as a number, you can use the following code:

>++++++++++<<[->+>-[>+>>]>[+[-<+>]>+>>]<<<<<<]>>[-]>>>++++++++++<[->-[>+>>]>[+[-
<+>]>+>>]<<<<<]>[-]>>[>++++++[-<++++++++>]<.<<+>+>[-]]<[<[->-<]++++++[->++++++++
<]>.[-]]<<++++++[-<++++++++>]<.[-]<<[-<+>]

(The original post containing this algorithm.)

Multiplication in Brainf*ck

2 Answers2