TreeForm without overlap

Question

I sometimes run into the problem of labels in TreeForm being unreadable because of overlap. An example is below, can anyone see a way to get rid of overlap?

{{4, 5, 6}, {{{2, 4, 5, 6}, {{{1, 2, 4}, {}}, {{2, 3, 6}, {}}}}, {{4, 
     5, 6, 8}, {{{4, 7, 8}, {}}, {{6, 8, 9}, {}}}}}} // TreeForm

_{(source: yaroslavvb.com)}

Belisarius' solution helps with overlap, but loses Tooltips, ie compare with

TreeForm[Hold[
  GraphPlotHighlight[edges : {((_ -> _) | {_ -> _, _}) ...}, 
    hl : {___} : {}, opts : OptionsPattern[]] := 
   Module[{verts, coords, g, sub}, 5]]]

_{(source: yaroslavvb.com)}

Answer update 11/12 I ended up using code below (belisarius' code with a minor fix)

myTreeForm[exp_] := 
  Module[{tooltipText, i}, 
   tooltipText = 
    Cases[Cases[MakeBoxes[TreeForm@exp, StandardForm], 
      TooltipBox[x__] -> x, 7, Heads -> True], 
     TagBox[x__, y__] -> DisplayForm[First@{x}], Heads -> True];
   i = 0;
   TreeForm[exp, 
    VertexRenderingFunction -> ({Tooltip[
         Inset[Rasterize[Text[" " <> ToString@#2 <> " "], 
           Background -> LightBlue], #1], tooltipText[[i++]]]} &)]];

Are you talking about this http://stackoverflow.com/q/4091728/421225 ? — Dr. belisarius, Nov 09 '10 at 21:12
There is a [`Tooltip`](http://reference.wolfram.com/mathematica/ref/Tooltip.html) directive which I expect you can use to take care of that, if you can figure out the string to put in it... — Cascabel, Nov 09 '10 at 22:40
@Jefromi Exactly! "if you can figure out the string to put in it" that is the tricky part. See my updated answer — Dr. belisarius, Nov 09 '10 at 23:57

Dr. belisarius · Accepted Answer · 2010-11-13T01:29:27.937

I did this before, but never generalized the result.

    rectOffset = {.25,.1};
    fontSize = 10
    TreeForm[list, 
          VertexRenderingFunction -> ({White, EdgeForm[Black], 
          Rectangle[#1 - rectOffset, #1 + rectOffset], Black, 
          Text[ Style[#2, fontSize], #1]} &)]

alt text

Edit With Tooltips

Using a "different approach"

Code is dirty, sorry no time to clean it up right now

rectOffset = {.33, .1};
fontSize = 9;
p = Cases[
   Cases[MakeBoxes[TreeForm@list, StandardForm], TooltipBox[x__] -> x,
     7, Heads -> True], TagBox[x__, y__] -> DisplayForm[First@{x}], 
   Heads -> True];
i = 0;
TreeForm[list, 
 VertexRenderingFunction -> ({White, EdgeForm[Black], 
     Rectangle[#1 - rectOffset, #1 + rectOffset], Black, 
     Tooltip[Text[Style[#2, fontSize], #1], p[[i++]]]} &)]

Output

alt text

Edit 2

I think this version is better:

Clear["Global`*"];
list = Hold[
   GraphPlotHighlight[edges : {((_ -> _) | {_ -> _, _}) ...}, 
     hl : {___} : {}, opts : OptionsPattern[]] := 
    Module[{verts, coords, g, sub}, 5]];

myTreeForm[exp_] :=

  Module[{ps, tooltipText, i},

   ps[text_] := Rasterize[Text[Style[text]], "RasterSize"];

   tooltipText = 
    Cases[Cases[MakeBoxes[TreeForm@list, StandardForm], 
      TooltipBox[x__] -> x, 7, Heads -> True], 
     TagBox[x__, y__] -> DisplayForm[First@{x}], Heads -> True];

   i = 0;

   TreeForm[list,
    EdgeRenderingFunction -> ({Red, Line[#1]} &), 
    VertexRenderingFunction -> ({White, EdgeForm[Black], {}, Black,
        Tooltip[
         Inset[Rasterize[Text[" " <> ToString@#2 <> " "], 
           Background -> LightBlue], #1], tooltipText[[i++]]]} &)]
   ];

list // myTreeForm

Output:

alt text

Edit 4 ... and last one

Cleaned up code, remove spurious functions and variables that were there just to complicate things:

myTreeForm[list_] := Module[{tooltipText, i},  

   tooltipText =   
         Cases[Cases[MakeBoxes[TreeForm@list, StandardForm],   
                    TooltipBox[x__] -> x, 7, Heads -> True],   
              TagBox[x__, y__] -> DisplayForm[First@{x}], Heads -> True];  
   i = 0;  
   TreeForm[list,  
           VertexRenderingFunction ->  
             ({Tooltip[Inset[Rasterize[Text[" " <> ToString@#2 <> " "], 
                       Background -> LightBlue], #1], tooltipText[[i++]]]} &) 
   ]  
 ];

HTH!

That's useful...one disadvantage is that it loses Tooltip with the subtree in StandardForm, added example in edit — Yaroslav Bulatov, Nov 09 '10 at 19:06
@Yaroslav I don't get what do you mean by "loses Tooltip with the subtree in StandardForm". What are your expected results? — Dr. belisarius, Nov 09 '10 at 21:23
@Yaroslav To get a general solution it should scale the rectangles and edges with the text lenght using VertexRenderingFunction/VertexCoordinateRules and EdgeRenderingFunction. Otherwise you have to customize rectoffset and fontSize for each Graph. Also please note that the MakeBoxes[] output may not port well for future versions, but it makes the trick for getting the Tooltip text for each subtree. — Dr. belisarius, Nov 10 '10 at 12:20
btw, I think you need myTreeForm[list_] instead of myTreeForm[exp_] — Yaroslav Bulatov, Nov 12 '10 at 20:34
@Yaroslav Yes, tnx. I had the var "list" defined one cell above. That was why it worked in my .nb — Dr. belisarius, Nov 13 '10 at 01:28

score 0 · Answer 2 · answered Nov 09 '10 at 18:15

0

It looks as if the option VertexCoordinateRules may be your best hope.

answered Nov 09 '10 at 18:15

High Performance Mark

77,191
7
105
161

TreeForm without overlap

2 Answers2