Closing Excel in a Background worker

Question

I have the following code that is supposed to run in a background worker when I hit the red X button to close the form:

Private Sub Form1_FormClosed(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles MyBase.FormClosed
    picLoading.Visible = True
    tblMain.Visible = False
    bwQuitNoSave.RunWorkerAsync()

End Sub

Private Sub bwQuitNoSave_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles bwQuitNoSave.DoWork
    'If at least one sheet has been opened, close the workbook
    If FirstLoad = 2 Then
        worksheet.Cells(1, 31).Value = ""
        workbook.Save()
        workbook.Close(False)
    End If
End Sub

Private Sub bwQuitNoSave_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles bwQuitNoSave.RunWorkerCompleted
    'Exit the application
    APP.Quit()
End Sub

So what's supposed to happen is that the application checks to see if an integer = 2, and if it is, it saves the workbook, closes it, and then quits the application. However when I run this code, even when the application is closed, the excel process stays open.

In a previous iteration of my application, I was using this code which functioned correctly (e.g. closed out the excel process):

Private Sub Form1_FormClosed(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles MyBase.FormClosed

   picLoading.Visible = True
   tblMain.Visible = False

   'If at least one sheet has been opened, close the workbook
   If FirstLoad = 2 Then
       worksheet.Cells(1, 31).Value = ""
       workbook.Save()
       workbook.Close(False)
   End If
   'Exit the application
       APP.Quit()

End Sub

Does anyone see what I'm missing?


I've also tried this, and the process still remains open:

 Private Sub bwQuitNoSave_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles bwQuitNoSave.DoWork
        'If at least one sheet has been opened, close the workbook
        If FirstLoad = 2 Then
            worksheet.Cells(1, 31).Value = ""
            workbook.Save()
            workbook.Close(False)
        End If
    Try
        workbook.Close(False)
        APP.Quit()
    Catch
        APP.Quit()
    End Try
    End Sub

    Private Sub bwQuitNoSave_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles bwQuitNoSave.RunWorkerCompleted
        'Exit the application
        releaseMemory(APP)
        releaseMemory(worksheet)
        releaseMemory(workbook)

    End Sub

    Private Sub releaseMemory(ByVal obj As Object)
        Try
            System.Runtime.InteropServices.Marshal.ReleaseComObject(obj)
            obj = Nothing
        Catch ex As Exception
            obj = Nothing
        Finally
            GC.Collect()
        End Try
    End Sub

Solved it after many, many tries:

Private Sub Form1_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
    If e.CloseReason = CloseReason.UserClosing Then
        e.Cancel = True
        picLoading.Visible = True
        tblMain.Visible = False
        If FirstLoad = 2 Then
            worksheet.Cells(1, 31).Value = ""
            bwQuitNoSave.RunWorkerAsync()
        Else
            Quit()
        End If
    End If
End Sub
Public Sub Quit()
    APP.Quit()
    GC.Collect()
    GC.WaitForPendingFinalizers()
    GC.Collect()
    GC.WaitForPendingFinalizers()
    Application.Exit()
End Sub
Private Sub bwQuitNoSave_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles bwQuitNoSave.DoWork
    'If at least one sheet has been opened, close the workbook
    workbook.Save()
End Sub

Private Sub bwQuitNoSave_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles bwQuitNoSave.RunWorkerCompleted
    Quit()
End Sub

Turns out the key was to have the exit via the red X canceled and manually close out the application.