Mustache not rendering JSON value as JSON encoded string

Question

The full example is here:

{-# LANGUAGE OverloadedStrings #-}
module Test2 where

import Data.Aeson
import Text.Mustache

main :: IO ()
main = do
  let example = Data.Aeson.object [ "key" .= (5 :: Integer), "somethingElse" .= (2 :: Integer) ]
  print . encode $ example
  print ("Start" :: String)
  case compileTemplate "" "{{{jsonData}}}" of
    Right x -> do
      print $ substituteValue x (Text.Mustache.object ["jsonData" ~= example])
    Left e -> error . show $ e

The above produces the following output:

"{\"somethingElse\":2,\"key\":5}"
"Start"
"fromList [(\"somethingElse\",2.0),(\"key\",5.0)]"

My expectation is it would produce:

"{\"somethingElse\":2,\"key\":5}"
"Start"
"{\"somethingElse\":2,\"key\":5}"

I can't reproduce your output – the first line is missing. Can you fix that? — sjakobi, Feb 14 '17 at 11:31
Apologies, I added an extra print and forgot to update the code. It should now produce the output as stated (from within GHCi). — Chris Stryczynski, Feb 14 '17 at 12:22
I think this could be a bug in mustache. I suggest you open an issue. — sjakobi, Feb 14 '17 at 15:53

score 1 · Accepted Answer · edited May 23 '17 at 11:54

Mustache doesn't seem to support straight substitution of JSON objects. Setting up a similar example here, I receive

[object Object]

as output. Not identical to yours, but it indicates that the issue is not necessarily with the Haskell implementation.

In other words, I believe the issue is with your template {{{jsonData}}}.

If you change it to {{{jsonData.somethingElse}}}, it works fine (I know this is not what you want).

Alternatively, encode the JSON data as text prior to passing it to the substitution function as suggested here. Basically something like this:

substituteValue x (Text.Mustache.object ["jsonData" ~= (encodeToLazyText jsonData)])

This results in your desired output. encodeToLazyText is found in Data.Aeson.Text.

Working code:

{-# LANGUAGE OverloadedStrings #-}

module Main where

import           Data.Aeson ((.=))
import qualified Data.Aeson as A
import           Data.Aeson.Text (encodeToLazyText)
import           Text.Mustache ((~=))
import qualified Text.Mustache as M
import qualified Text.Mustache.Types as M

main :: IO ()
main = do
  print . A.encode $ jsonData
  putStrLn "Start"
  case M.compileTemplate "" "in mustache: {{{jsonData}}}" of
    Right template ->
      print (M.substituteValue template mustacheVals)
    Left e -> 
      error . show $ e

jsonData :: A.Value
jsonData = 
  A.object
    [ "key" .= (5 :: Integer)
    , "somethingElse" .= (2 :: Integer)
    ]

mustacheVals :: M.Value
mustacheVals =
  M.object
    [ "jsonData" ~= encodeToLazyText jsonData
    ]

I incorrectly assumed the JSON functionality had to do with rendering JSON values. — Chris Stryczynski, Feb 14 '17 at 17:05

Mustache not rendering JSON value as JSON encoded string

1 Answers1