Why does a centered MessageDlg create exceptions?

Question

Delphi 6.
I implemented a MessageDlg centered on the owner form
as suggested by @David Heffernan on january 6 2011.

The original question from 2011 is here: How to make MessageDlg centered on owner form.

The centered dialog works once.
After the first time it throws exceptions.
- EAccessViolation
- Access violation at address 00000000
- Read of address 00000000

What might I have done wrong to cause this?

function TEthernetNodes_form.CenteredMessageDlg(const Msg: string;
                                                DlgType:   TMsgDlgType;
                                                Buttons:   TMsgDlgButtons;
                                                HelpCtx:   Integer): Integer;
// Open a message Dialog in the center of the owner form
var
  Dialog: TForm;
begin
  Result := mrNo; // Suppress linker warning
  try
    Dialog := CreateMessageDialog(Msg, DlgType, Buttons);
    try
      Self.InsertComponent(Dialog);
      Dialog.Position := poOwnerFormCenter;
      Result := Dialog.ShowModal
    finally
      Dialog.Free
    end;

  except on E: Exception do
               begin
                 AddToActivityLog('Exception in CenteredMsgDlg: [' +  
                                   string(E.ClassName) + ']' +  
                                   E.Message, True, True);  
                 //Tried "ShowMEssage" instead of AddToActivityLog here. Does not display.
               end;

  end;
end;  

procedure TEthernetNodes_form.Button1Click(Sender: TObject);
begin
  CenteredMessageDlg('Test CenteredMessageDlg.', mtConfirmation, [mbOK], 0);
end;

The exception is shown in my activity log as follows:

Exception in CenteredMsgDlg: [EAccessViolation] Access violation at  
address 00000000. Read of address 00000000

score 6 · Accepted Answer · answered Feb 23 '17 at 19:13

6

CreateMessageDialog creates form with Application as its Owner - it is added to Application components list. With Self.InsertComponent(Dialog); you are adding it to your forms component list, but it is not removed from Application's.

var
  Dialog: TForm;
begin
  Result := mrNo; // Suppress linker warning
  try
    Dialog := CreateMessageDialog(Msg, DlgType, Buttons);
    try
      Application.RemoveComponent(Dialog); // remove Dialog from Application components
      Self.InsertComponent(Dialog);
      Dialog.Position := poOwnerFormCenter;
      Result := Dialog.ShowModal;
    finally
      Dialog.Free
    end;

answered Feb 23 '17 at 19:13

Dalija Prasnikar

27,212
44
82
159

From what I can see, `RemoveComponent` is called within `InsertComponent`. I haven't traced the call at runtime though. – LU RD Feb 23 '17 at 23:00
@Dalija Prasnikar I can confirm that your suggestion solved the problem. Many thanks. – AndersJ Feb 24 '17 at 08:01
Ok, D6 `InsertComponent` does not call `RemoveComponent`, but D2007 does. Can't check versions between that. – LU RD Feb 24 '17 at 08:43
@LURD D7 also does not call `RemoveComponent` That code was improved later. – Dalija Prasnikar Feb 24 '17 at 10:26
Just checked D2006, and it does call `RemoveComponent`. – LU RD Feb 24 '17 at 10:27
Will there be issues if I upgrade to a Delphi version that calls RemoveComponent, now that I explicitly added it? – AndersJ Feb 24 '17 at 16:03
No, you should not have any issues because of that. – Dalija Prasnikar Feb 24 '17 at 16:17

Why does a centered MessageDlg create exceptions?

1 Answers1