Procedure with assumed-shape dummy argument must have an explicit interface

Question

I am completely new to Fortran 90 and I am trying to understand how to pass an array to a function. I looked on the web and I could not find any clear and simple enough example, so I decided to post here.

I would like the function be able to work on an array of any length (the length of the array should not be one of the parameters of the functions).

I tried to write a simple example of a function that returns the sum of the elements of an array:

function mysum(arr)
    implicit none
    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
end function mysum

program test
    implicit none
    real, dimension(4) :: a
    real :: mysum,a_sum
    call random_number(a)
    print *,a
    a_sum=mysum(a)
    print *,a_sum
end program

When I try to compile, I get the following error:

array_test.f90:17.14:

 real mysum,a_sum
           1
Error: Procedure 'mysum' at (1) with assumed-shape dummy argument 'arr' must have an explicit interface

What is the problem with my program?

Please use the tag [tag:fortran], Fortran 90 is just one old version. I could have closed your question now... — Vladimir F Героям слава, Mar 13 '17 at 15:07
It was treated here quite a few times. The procedure must be in a module or internal, or an interface block must be provided at the call site. Modules are preferred. — Vladimir F Героям слава, Mar 13 '17 at 15:08
If you want to write modern style Fortran *All procedures should be inside a module*. — Vladimir F Героям слава, Mar 13 '17 at 15:11
@VladimirF Ok, I will check out these modules then (and interfaces). I read the question you pointed out as possible duplicate, but unfortunately my current level of Fortran is too low to understand how exactly I can use the concept of module and interface to solve my problem. — valerio, Mar 13 '17 at 15:16
OK, let's make a simpler answer to this exact error message. — Vladimir F Героям слава, Mar 13 '17 at 15:25
related http://stackoverflow.com/questions/24543329/assumed-size-arrays-colon-vs-asterisk-dimension-arr-vs-arr — agentp, Mar 13 '17 at 15:55

score 12 · Accepted Answer · edited Sep 28 '17 at 00:23

Assumed shape dummy arguments (those with (:)) require explicit interface to the procedure to be available at the call site. That means the calling code must know how exactly the subroutine header looks like. See also Module calling an external procedure with implicit interface

That explicit interface can be provided in several ways

1. preferred - a module procedure

module procedures
  implicit none

contains

  function mysum(arr)

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end module

program test
    use procedures

    implicit none
    !no mysum declared here, it comes from the module
    ...
end program

2. internal procedure - only for short simple procedures or if the procedure needs access to the host's variables. Because of the access to the host variables it is error-prone.

program test
    implicit none
    !no a_sum declared here, it is visible below contains
    ...    
contains

  function mysum(arr)

    !implicit none inherited from the program

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end program

3. interface block - not recommended at all, you should have some particular reason to use it

function mysum(arr)
  ! removed to save space
end function mysum

program test
    implicit none

     interface
       function mysum(arr)
         real, dimension(:), intent(in) :: arr
         real :: mysum
       end function
     end interface

     !no mysum declared there
     !it is declared in the interface block
     ...
end program

Thank you very much, the first method (module) solved my problem perfectly and helped me understand better the concept of module and interface. To be more specific, If someone wants to try this example, to make it work I had to replace, in 'program', "real :: mysum,a_sum" with "real :: a_sum". — valerio, Mar 13 '17 at 15:49
Yes, that must be removed. Also any `external` must be removed. I forgot to check it (it does not have to be there for subroutines). — Vladimir F Героям слава, Mar 13 '17 at 16:04

Procedure with assumed-shape dummy argument must have an explicit interface

1 Answers1

Linked

Related