flexunit of handle customer event and Async.asyncHandler()

Question

Any one know how does Async.asyncHandler() work and if Async.processOnEvent() can only used in [Before] method.(Any one know some helpful document besides http://docs.flexunit.org/).

I define a MXML component named HelloCompo(extends Vbox), and the component define a function named hello(), in the hello() dispacthed a customer event named HelloEvent(the event type just named "hello"), and in another function named init() listened for the event, I want to test whether the event is dispatched properly or not. So I have the test following:

var helloCompo = new HelloCompo();

helloCompo.hello();

helloCompo.addEventListener("hello", Async.asyncHandler(this, handleHello, 1000, null, handleTimeOut));

The test will always excute the handleTimeOut method(means the HelloEvent is not dispatched, but when helloCompo.hello() excute, it really dispacthed, so what's going wrong?)

score 6 · Accepted Answer · answered Nov 28 '10 at 13:26

package flexUnitTests
{
    import flash.events.Event;

    import org.flexunit.asserts.assertTrue;
    import org.flexunit.asserts.fail;
    import org.flexunit.async.Async;

    public class HelloTest
    {       
        private var helloCompo:HelloCompo;

        [Before]
        public function setUp():void
        {
            helloCompo = new HelloCompo();
        }

        [After]
        public function tearDown():void
        {
            helloCompo = null;
        }

        [Test(async)]
        public function testHello():void
        {
            var handler:Function = Async.asyncHandler(this, helloHandler, 300, null, helloFailed);
            helloCompo.addEventListener("hello", handler);
            helloCompo.hello();
        }

        private function helloHandler(event:Event, passThroughObject:Object):void
        {
            //assert somthing
        }

        private function helloFailed(event:Event, passThroughObject:Object):void
        {
            fail("hello not dispatched");
        }


    }
}

HelloCompo.as

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;

    public class HelloCompo extends EventDispatcher
    {
        public function HelloCompo(target:IEventDispatcher=null)
        {
            super(target);
        }

        public function hello():void
        {
            dispatchEvent(new Event("hello"));
        }
    }
}

Florian F · Answer 2 · 2010-11-28T11:23:31.540

2

I think you need to add your event listener before calling hello() actually

edited Nov 28 '10 at 11:23

answered Nov 27 '10 at 13:42

Florian F

8,822
4
37
50

@pez. Sorry, I don't think so – jason Nov 28 '10 at 10:41
Yeah my bad, you're right. I made a quick test and it works fine. Are you sure you put the async property on your Test tag? – Florian F Nov 28 '10 at 11:21
I had put async property on Test tag. What do you mean "add evrnt listener" before calling hello()"?. You mean : helloCompo.addEventListener(), then helloCompo.hello()? but still not work, so can you put your code? – jason Nov 28 '10 at 12:19
ok, I made a new answer because I couldn't post code in my comment – Florian F Nov 28 '10 at 13:25

flexunit of handle customer event and Async.asyncHandler()

2 Answers2