Perl script to populate an XML file

Question

I am working on a Perl script which needs to populate an XML file based on user input. The user would provide a country name and a city name. If he/she provides: japan and e, I need to populate that in the japan tag - but as the last entry. How best can I achieve this? The cities in country tag can be many. How can I add a city as a last tag inside corresponding country tag?

How can I reach at the end of relevant country tag each time I need to add a city?

PS: I am not using any in-built data structures to store data. I am just adding dumb lines in the file.

Samlple output XML file:

<country name="japan-">
  <city>a</city>
  <city>b</city>
  <city>c</city>
  <city>d</city>
</country>
<country name="china-">
  <city>aa</city>
  <city>bb</city>
  <city>cc</city>
  <city>dd</city>
</country>

I've a more concrete question, Change an XML file content via Perl script.

score 4 · Accepted Answer · answered Nov 28 '10 at 21:43

XML::Simple is... Simple. :) It does require a root element though:

#!/usr/bin/env perl

use strict;
use warnings;

use XML::Simple;
use Data::Dumper;

my $xml = join "\n", <DATA>;
my $doc = XMLin($xml, KeepRoot => 1);

# Get the list of cities as a list, then push "Tokyo" to it.
push @{$doc->{countries}->{country}->{'japan-'}->{city}}, 'Tokyo';

print XMLout($doc, KeepRoot => 1);

__DATA__
<countries>
    <country name="japan-">
        <city>a</city>
        <city>b</city>
        <city>c</city>
        <city>d</city>
    </country>
    <country name="china-">
        <city>aa</city>
        <city>bb</city>
        <city>cc</city>
        <city>dd</city>
    </country>
</countries>

Output:

<countries>
  <country name="china-">
    <city>aa</city>
    <city>bb</city>
    <city>cc</city>
    <city>dd</city>
  </country>
  <country name="japan-">
    <city>a</city>
    <city>b</city>
    <city>c</city>
    <city>d</city>
    <city>Tokyo</city>
  </country>
</countries>

Great Mikael :) How can I parse an existing xml file and then add an entry to it? — hari, Nov 28 '10 at 21:57
Thanks Mikael, I also need to add new country when user ask for adding a country which is not there already. — hari, Nov 28 '10 at 22:47
Hi Mikael, I am not able to reach to exact node, I guess. My "push" is not working as expected. — hari, Nov 29 '10 at 07:42

score 0 · Answer 2 · edited Oct 06 '15 at 10:41

0

I think you meant: How do I load an XML file and add entries to it based on user input?

If I understood that right: You use a parser/writer like XML::Simple (there are apparently better ones like XML::Twig too, so explore a bit) to load the file into a Perl data structure of hashes and arrays. (Use Data::Dumper to check how it looks like in memory.) Then you edit that structure with normal Perl data interaction and when done use the writer to convert it back to XML.

edited Oct 06 '15 at 10:41

Peter Mortensen

30,738
21
105
131

answered Nov 28 '10 at 21:41

Mithaldu

2,393
19
39

Sorry for the confusion. I know how to write xml content. My question is about how to add a city as a last entry in country tag. Do I need to walk through all the existing city entries and when I reach the last tag, I need to add the newly requested city there. How to achieve that? – hari Nov 28 '10 at 21:44
Uh, if you read the XML file with a parser you'll have a hash of countries, sorted by key (in the best case), each containing an array of cities for each country. So you just select the right value from the country hash, get its city array and push onto that array. Where's the difficulty? – Mithaldu Nov 28 '10 at 21:55
Thanks Mithaldu, I am still learning to work with XML in perl. – hari Nov 29 '10 at 00:51

score 0 · Answer 3 · answered Nov 29 '10 at 05:44

Below is a solution using XML::Twig. I think it does what you want. The most notable features of XML::Twig it uses are the use of id => name option to treat the name attribute as an ID so elements can be found directly with $t->elt_id, and the insert_new_elt method to creates a new element in the tree. Its signature is ( <position: before, after, first_child or last_child>, <tag_name>, <{attributes}>, <content>),

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

my $t= XML::Twig->new( id => 'name',  # treat the name attribute as an ID
                       pretty_print => 'indented'
                     )
                ->parse( \*DATA);

add_city( $t, japan => "Kobe");
add_city( $t, japan => "Tokyo");
add_city( $t, china => "Beijing");
add_city( $t, china => "Shanghai");
add_city( $t, japan => "Kobe");
add_city( $t, south_korea => "Seoul");

$t->print;

sub add_city
  { my( $t, $country_name, $city_name)= @_;

    my $country= $t->elt_id( $country_name);
    if( ! $country)
      { warn "creating country '$country_name'\n"; 
        $country= $t->root->insert_new_elt( last_child => country 
                                            => { name => $country_name }
                                          );
      }

    if( $country->first_child( qq{city[text()="$city_name"]}))
      { warn "city '$city_name' already found in '$country_name', skipping\n"; 
        return;
      }

    warn "adding '$city_name' to '$country_name', skipping\n";
    $country->insert_new_elt( last_child => 'city', $city_name);
  }


__DATA__
<countries>
  <country name="japan">
  </country>
  <country name="china">
  </country>
</countries>

Thanks Mirod for the answer. In my case I need to make changes (addition) to an existing xml file. How can I load my existing xml file? — hari, Nov 29 '10 at 06:30
Appreciate for your help. I've posted more concrete question here: http://stackoverflow.com/questions/4301435/change-an-xml-file-content-via-perl-script — hari, Nov 29 '10 at 06:44
the xml file is loaded when the parse method is called. You can then access the elements through navigation, using first/last_child, children, parent or prev/next_siblin, directly using elt_id or using XPath with findnodes, finvalue... — mirod, Nov 29 '10 at 07:45

Perl script to populate an XML file

3 Answers3

Linked