Select Case With Conditions ( Classic ASP)

Question

<%
i=2 
  Select Case i
  Case 1,2,3,4,5,7,8,9,10
    response.write("Grade A")
  Case 11,12,13,14,15,16,17,18,19,20  
    response.write("Grade B")
  Case 21,22,23,24,25,26,27,28,29,30
    response.write("Grade C")
  Case 31,32,33,34,35,36,37,38,39,40
    response.write("Grade D")
  Case Else
    response.write("Invalid")
  End Select
  %>

how to replace 1,2,3.. with a smaller statement. I have tried putting 1 To 10 but it is showing error.

Appreciate any help , thank you!

MC ND · Answer 1 · 2017-04-04T21:12:45.127

5

Some alternatives

grade = "Invalid"
Select Case True
    Case i < 1   
    Case i < 11 : grade = "Grade A"
    Case i < 21 : grade = "Grade B"
    Case i < 31 : grade = "Grade C"
    Case i < 41 : grade = "Grade D"
End Select

or

If i > 0 And i < 41 Then 
    grade = "Grade " + Chr(Asc("A") + (i-1)\10)
Else 
    grade = "Invalid"
End If

or

If i > 0 And i < 41 Then 
    grade = Array("Grade A", "Grade B", "Grade C", "Grade D")((i-1)\10)
Else 
    grade = "Invalid"
End If

edited to correct the error pointed by Ekkehard.Horner

edited Apr 04 '17 at 21:12

answered Apr 04 '17 at 19:39

MC ND

69,615
8
84
126

1

32 is a counter example for alt. 2. – Ekkehard.Horner Apr 04 '17 at 20:12
@Ekkehard.Horner, of course, you are right. I should not post while being called for dinner. My fault. – MC ND Apr 04 '17 at 20:40

score 0 · Answer 2 · answered Apr 04 '17 at 18:13

As your specs boil down to a regular/computable mapping, Select Case or If .. ElseIf - i.e. cherry picking - are the wrong tools anyway:

Option Explicit

Dim i

For i = -1 to 42
    If 1 > i Or 40 < i Then
       WScript.Echo i, "invalid"
    Else
       WScript.Echo i, Chr(65 + ((i - 1) \ 10))
    End If
Next

output:

cscript 43214055.vbs
-1 invalid
0 invalid
1 A
2 A
3 A
4 A
5 A
6 A
7 A
8 A
9 A
10 A
11 B
12 B
13 B
14 B
15 B
16 B
17 B
18 B
19 B
20 B
21 C
22 C
23 C
24 C
25 C
26 C
27 C
28 C
29 C
30 C
31 D
32 D
33 D
34 D
35 D
36 D
37 D
38 D
39 D
40 D
41 invalid
42 invalid

score -2 · Answer 3 · answered Apr 04 '17 at 17:56

You're using VBScript in your page. It has no support of ranges in a Select Case statement. You may be better off using If/ElseIf statements.

<%
    i=2
    If i > 0 And i <= 10 Then
        Response.Write("Grade A")
    ElseIf i > 10 And i <= 20 Then
        Response.Write("Grade B")
    ElseIf i > 20 And i <=30 Then
        Response.Write("Grade C")
    ElseIf i > 30 And i <= 40 Then
        Response.Write("Grade D")
    Else
        Response.Write("Invalid")
    End If
%>

Select Case With Conditions ( Classic ASP)

3 Answers3