How to parse a JSON string in Delphi?

Question

How can I parse the JSON string

{"data":{"results":[{"Branch":"ACCT590003"}]}}

using the TJSONObject object? I want to get the ACCT590003 value from this string.

score 38 · Answer 1 · answered Jul 02 '18 at 10:23

38

You don't need to use external libraries to perform a JSONPath search. Example with Delphi 10 Seattle:

uses  System.JSON;
procedure ParseJSonValue;
var
   JSonValue:TJSonValue;
   st:string;
   Branch: string;
begin
   st := '{"data":{"results":[{"Branch":"ACCT590003"}]}}';
   JsonValue := TJSonObject.ParseJSONValue(st);
   Branch := JsonValue.GetValue<string>('data.results[0].Branch');
   JsonValue.Free;
end;

answered Jul 02 '18 at 10:23

jaruzafa

676
6
8

The original question was about creating an instance of `TJSonObject` and not about receiving a `TJsonValue`.. ^^ – Christopher Stock Apr 02 '20 at 12:24
2

This solution is perfect! Thanks! – Kevin Berry Feb 03 '22 at 21:12
This is much easier than my attempt to use TJsonIterator – WeststarEric Jul 29 '22 at 20:58
1

To convert to JSONObjet , do CAST: MyJSONObject := (JsonValue as TJSONObject); – Roberto Novakosky Sep 30 '22 at 00:22

score 21 · Answer 2 · answered Dec 04 '10 at 02:33

uses
  SysUtils,
  DBXJSON;

type
  TProcessJSONString = TProc<TJSONString>;

procedure DoJSONObject(o: TJSONObject; Process: TProcessJSONString); forward;

procedure DoJSONArray(o: TJSONArray; Process: TProcessJSONString);
var i: integer;
    v: TJSONValue;
begin
  for i := 0 to o.Size - 1 do begin
    v := o.Get(i);
    if v is TJSONObject then
      DoJSONObject(v as TJSONObject, Process);
  end;
end;

procedure DoJSONObject(o: TJSONObject; Process: TProcessJSONString);
var i: integer;
    p: TJSONPair;
begin
  for i := 0 to o.Size - 1 do begin
    p := o.Get(i);
    Process(p.JsonString);
    if p.JsonValue is TJSONObject then
      DoJSONObject(p.JsonValue as TJSONObject, Process)
    else if p.JsonValue is TJSONArray then
      DoJSONArray(p.JsonValue as TJSONArray, Process)
    else if p.JsonValue is TJSONString then
      Process(p.JsonValue as TJSONString);
  end;
end;

var o: TJSONObject;
begin
  o := TJSONObject.ParseJSONValue('{"data":{"results":[{"Branch":"ACCT590003"}]}}') as TJSONObject;
  try
    DoJSONObject(o,
      procedure (o: TJSONString)
      begin
        WriteLn(o.ToString);
      end
    );
  finally
    o.Free;
  end;
  ReadLn;
end.

While good, it's generally preferred to use the system available libraries to keep maintaining the code easier. — T.S, Aug 21 '19 at 11:06

score 10 · Answer 3 · answered Feb 19 '17 at 23:24

Try this code, it works fine

uses System.JSON;

procedure _Parse_JSonValue;
var
   JSonObject:TJSonObject;
   JSonValue:TJSonValue;
   st:string;
   Branch: string;
Begin
   st := '{"data":{"results":[{"Branch":"ACCT590003"}]}}';
   JSonObject := TJSonObject.Create;
   JsonValue:=JSonObject.ParseJSONValue(st);
   JsonValue:=(JsonValue as TJSONObject).Get('data').JSONValue;
   JsonValue:=(JsonValue as TJSONObject).Get('results').JSONValue;
   if (JSONValue is TJSONArray) then
      Branch := ((JSONValue as TJSONArray).Items[0] as TJSonObject).Get('Branch').JSONValue.Value;
   JSonObject.Free;
End;

Branch = 'ACCT590003'

score 5 · Answer 4 · answered Nov 18 '15 at 21:06

5

using TALdocument it's easy

AJsonDoc := TalJsonDocument.create;
AjsonDoc.loadFromJsonString('{"data":{"results":[{"Branch":"ACCT590003"}]}}');
writeln(AjsonDoc.childnode['data']['result'][0]['Branch'].text);

answered Nov 18 '15 at 21:06

zeus

12,173
9
63
184

score 5 · Answer 5 · answered Apr 27 '16 at 14:00

Using SuperObject Library https://github.com/hgourvest/superobject/

var json: iSuperObject;
    data: string;

begin
  json := SO('{"data":{"results":[{"Branch":"ACCT590003"}]}}'); // shorthand
// or equal:  JSON := TSuperObject.ParseString('{"data":{"results":[{"Branch":"ACCT590003"}]}}');

  data := json.S['data.results[0].Branch'];

  WriteLn('Result is: ', data);
end.

How to parse a JSON string in Delphi?

5 Answers5

Linked