Creating a folder according to today's date and copying files into the new folder using batch files

Question

I have the following code that creates a folder based on today's date and moves the file from a folder to the new one. I have the following code:

set date="%date:~7,2%%date:~4,2%%date:~10,4%"
set mydir=%date%
cd "C:\Users\rnan\Desktop\Batch Files\Tess\File History\"
mkdir "C:\Users\rnan\Desktop\Batch Files\Tess\File History\%mydir%"
"C:\Program Files (x86)\WinSCP\WinSCP.com" /command ^
"open ftp://rnan:J13@Files8.cyberlynk.net/tess/" ^
"lcd ""C:\Users\rnan\Desktop\Batch Files\Tess\File History\%mydir%""" ^ 
"get *.csv>1D" ^ 
"exit"

This code creates a folder but doesn't copy any files to the newly created folder. The files are being copied from FTP server to the new folder. Please suggest some changes that copies those files.

Thanks!

*"This code creates a folder but doesn't copy any files to the newly created folder."* - So what does it do? Show use script output and log file (`"C:\Program Files (x86)\WinSCP\WinSCP.com" /log=winscp.log`) — Martin Prikryl, Apr 21 '17 at 13:18
@Rahul Also, did you put the commands to a .bat file, right? — Martin Prikryl, Apr 21 '17 at 14:27

Martin Prikryl · Accepted Answer · 2018-04-30T19:29:13.697

Your code is correct in general (except for the date variable misuse, as @Jeff pointed out).

You most probably have just wrong white spaces around the ^.

The ^ has to be the very last character on the line. You seem to have spaces after ^ on the lines with lcd and get.
The line following the ^ has to start with a space. You do not have any spaces on the following lines.

See WinSCP FAQ Why are some scripting commands specified on WinSCP command-line in a batch file not executed/failing?

Also not only you should not assign to date variable. You should not even use it this way to format timestamp, as the format of the date variable in locale-specific. See Creating a file name as a timestamp in a batch job. So, you better use another approach.

WinSCP itself supports date formatting using its %TIMESTAMP% syntax.

The following code fixed the issues with ^ and uses WinSCP to format date reliably:

set TIMESTAMP_FORMAT=yyyy-mm-dd
cd "C:\Program Files (x86)\WinSCP"
for /F "tokens=* USEBACKQ" %%F in (`WinSCP.com /command "echo %%TIMESTAMP#%TIMESTAMP_FORMAT%%%" "exit"`) do set TIMESTAMP=%%F
set mydir=C:\Users\rnan\Desktop\Batch Files\Tess\File History\%TIMESTAMP%
mkdir "%mydir%"
WinSCP.com /command ^
    "open ftp://rnan:J13@Files8.cyberlynk.net/tess/" ^
    "lcd ""%mydir%""" ^
    "get *.csv>1D" ^
    "exit"

Gerhard · Answer 2 · 2017-04-21T14:38:45.063

1

I do not have WinSCP installed, so this is untested, but why not try this?

set datetime=%date:~7,2%%date:~4,2%%date:~10,4%
set "mydir=C:\Users\rnan\Desktop\Batch Files\Tess\File History\%datetime%"
mkdir "%mydir%"
"C:\Program Files (x86)\WinSCP\WinSCP.com" /command ^
   "open ftp://rnan:J13@Files8.cyberlynk.net/tess/" ^
   "lcd ""%mydir%""" ^
   "get *.csv>1D" ^
   "exit"

edited Apr 21 '17 at 14:38

answered Apr 21 '17 at 13:32

Gerhard

22,678
7
27
43

You have still space after `^` in the `lcd` line. – Martin Prikryl Apr 21 '17 at 13:36
Yes sorry, I would have seen that if I tested it, but do not have winscp installed. thanks! – Gerhard Apr 21 '17 at 13:37
@GerhardBarnard yes I tried yours, it creates 2 separate files and shows the error of unknown command as i mentioned earlier – qwerty Apr 21 '17 at 14:37
@Rahul oh snap, forgot to add the quotes around `mkdir "mydir%"` – Gerhard Apr 21 '17 at 14:39
Moreover, it relies on locale-specific value of `date`. For example my system it would create folder `014.` – Martin Prikryl Apr 21 '17 at 14:39
Correct yes. I was just moving away from him modifying `date` as he did in the question. this format would however have worked for him. – Gerhard Apr 21 '17 at 14:41
@GerhardBarnard Thanks :) – qwerty Apr 21 '17 at 17:22
@martijn pieters Maybe in this case can we not delete that answer ( which was a comment). Since some people may find something useful ? – qwerty Apr 21 '17 at 20:08

score 1 · Answer 3 · edited Jul 03 '20 at 14:22

Here is a batch script which first creates a folder with name date&time and after that copies files from source folder and passes it on to the new folder:

echo off

for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
set CUR_YYYY=%year%
set CUR_MM=%month%
set CUR_DD=%day%


set CUR_HH=%time:~0,2%


set SOURCE=%C:\Work\Deployed-Content%
set TARGET=%C:\Work\%

if %CUR_HH% lss 10 (set CUR_HH=0%time:~1,1%)

set CUR_NN=%time:~3,2%
set CUR_SS=%time:~6,2%
set CUR_MS=%time:~9,2%


set FOLDERNAME=%CUR_YYYY%.%CUR_MM%.%CUR_DD%-%CUR_HH%-%CUR_NN%-%CUR_MS%
mkdir %FOLDERNAME%

robocopy %SOURCE%  %TARGET%%FOLDERNAME% /mir

echo Over and out.

Creating a folder according to today's date and copying files into the new folder using batch files

3 Answers3