9

When I read a directory in Perl with opendir, readdir, and closedir, the readdir function doesn't seem to read the files in any specific order (that I can tell).

I am reading a directory that has subdirectories named by epoch timestamp:

1224161460
1228324260
1229698140

I want to read in these directories in numerical order, which would put the oldest directories first.

When I use readdir, the first one it reads is 1228324260, which is the middle one. I know I could put the directory contents in an array and sort the array, but is there an option I can pass to readdir to read in sorted order? Or maybe a more elegant way of accomplishing this than pushing everything into array and sorting the array? There are probably modules out there to do this too, but it is difficult to get modules installed in our environment, so unless it is a built-in module I'd prefer to not use modules...

Thanks!

EDIT As requested, I am posting the code that I am using:

opendir( my $data_dh, $data_dir ) or die "Cannot open $data_dir\n";
while ( my $name = readdir($data_dh) ) {
    next if ( $name eq '.' or $name eq '..' );
    my $full_path = "${data_dir}/${name}";
    next unless ( -d $full_path );
    process_dir($full_path);
}
closedir($data_dh);
Robert P
  • 15,707
  • 10
  • 68
  • 112
BrianH
  • 7,932
  • 10
  • 50
  • 71

3 Answers3

14

readdir can be called in array context, so just do this:

opendir( my $data_dh, $data_dir) or die "Cannot open $data_dir\n";
my @files = sort { $a <=> $b } readdir($data_dh);
while ( my $name = shift @files ) {
...
Robert P
  • 15,707
  • 10
  • 68
  • 112
Andrew Barnett
  • 5,066
  • 1
  • 22
  • 25
  • You don't need the { $a <=> $b } block; the default suffices here. – Svante Jan 12 '09 at 18:05
  • 2
    NO, the default does NOT suffice. The default sorts lexically, not numerically. Timestamps preceding 2001-09-09T01:46:40 would sort as later than most timestamps after it, because it broke the 1,000,000,000 seconds barrier. – Leon Timmermans Jan 12 '09 at 19:12
  • Really though, opendir is overkill here. Your best bet would be to use glob() ... no directory handles to worry about. – Robert P Jan 13 '09 at 03:11
  • @RobertP With `glob` you're gonna get full names (unless `$data_dir` happens to be also a root one). That means one additional call to `basename` or `chdir`. Which the latter might be a problem in time. – Pavel Jan 28 '17 at 14:02
  • But then `readdir` might be bad as well, i.e. for file tests `-X` as you loose paths though. – Pavel Jan 28 '17 at 20:37
5

You can try it with a bit of Glob magic, glob appears to function in a sorted manner, so this: 

#  Glob in scalar context iterates the result set internally
while( defined( my $dir = glob($dir . '/*' ) ) ){ 
     print $dir, "\n";
    # $dir is fed ordered and with full names. 
}

or

# Glob in list context returns all results. 
for( glob($dir.'/*' ) ){ 
  print $dir , "\n";
  # also ordered. 
}

should work. Just be careful with glob, because this: 

 for(0..20){ 
   printf "%30s|%30s\n", glob($dir.'/*' ), glob($dir.'/*' );
 }

does something semi-magical, and prints the dir contents twice on each line. ie: 

/foo/bar/a  |  /foo/bar/a
/foo/bar/b  |  /foo/bar/b
/foo/bar/c  |  /foo/bar/c
/foo/bar/d  |  /foo/bar/d
Kent Fredric
  • 56,416
  • 14
  • 107
  • 150
5

Just throw a sort in front of any list operator that you want to re-order. You don't need to store the results in an array either. You can use a foreach:

opendir my($dh), $dirname or die "Could not open directory [$dirname]: $!";

foreach my $file ( sort { $a <=> $b } readdir $dh )
    {
    ...
    }
brian d foy
  • 129,424
  • 31
  • 207
  • 592