How to rename a download file in client side programmatically?

Question

I hope to download a file (such as http://www.example.com/my.zip) and rename it (such as rename my.zip to newfile.zip) when I save it to local disk.

I hope to write a code to do it, I don't know if VBScript can do it, or HTML can do it.

BTW, the following code doesn't work.

<!DOCTYPE html>
<html>
<head>
    <meta charset="utf-8" />
    <meta http-equiv="X-UA-Compatible" content="IE=Edge" />
    <title>HTML5 download Attribute Example</title>
</head>

<body>
<a href="https://ams-nl-ping.vultr.com/vultr.com.100MB.bin"
    download="newfile.zip">Download Your Expense Report</a>
</body>
</html>

Neither of those languages can automatically rename a file for you. Why not simply call the file what you want it to be downloaded as on the server (www.example.com/newfile.zip)? — Obsidian Age, May 08 '17 at 00:12
Can the save file dialog of a web browser fill in a new file name using code? — HelloCW, May 08 '17 at 00:42
I have read https://davidwalsh.name/download-attribute ,and place a download attribute on a link.. — HelloCW, May 08 '17 at 01:32
Thanks! I get the same result after I remove the semicolon. BTW the semicolon is added by stackoverflow. — HelloCW, May 08 '17 at 01:56
Don't try to automate the GUI. Download and save the file directly with VBScript. [Related](http://stackoverflow.com/a/20103315/1630171). — Ansgar Wiechers, May 08 '17 at 09:20
To Ansgar Wiechers: Could you show me some sample code? Thanks! — HelloCW, May 08 '17 at 10:36
@AnsgarWiechers the `X-UA-Compatible` flag on the HTML is set to `IE=Edge` so client-side VBScript will be unavailable. — user692942, May 08 '17 at 13:55
@AnsgarWiechers is running it from a website, not a requirement?, I guess if not, that will work. — user692942, May 08 '17 at 14:51
HTML isn't a scripting language. The HTML example here is misleading. I suggest removing it. — matt2000, May 16 '17 at 21:46
Try to follow the link. http://stackoverflow.com/questions/10049259/change-name-of-download-in-javascript — ecoder, May 17 '17 at 02:04

score 2 · Accepted Answer · answered May 10 '17 at 09:04

This should work without a HTML file (if that isn't a requirement), have tested it and it produces a 100MB zip file in C:\temp called newfile.zip.

Just remember when you execute the command, do so in an elevated context.

cscript //nologo "myscript.vbs"

Code myscript.vbs

Option Explicit

Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2

Call main()

Sub main()
  Dim url: url = "https://ams-nl-ping.vultr.com/vultr.com.100MB.bin"
  Dim path: path = "c:\temp\newfile.zip"
  Dim resp: resp = downloadFromURL(url)
  If Not IsEmpty(resp) Then
    Call SaveStreamToFile(resp, path)
  Else
    Call WScript.Echo("Failed to download from " & url)
  End If
End Sub

Function downloadFromURL(url)
  Dim http: Set http = CreateObject("MSXML2.XMLHTTP.6.0")
  Dim stream

  Call http.Open("GET", url, False)
  Call http.Send()

  If http.Status = 200 Then
    downloadFromURL = http.responseBody
  Else
    downloadFromURL = Empty
  End If
End Function

Sub SaveStreamToFile(resp, path)
    Dim stream: Set stream = CreateObject("ADODB.Stream")
    With stream
      Call .Open()
      .Type = adTypeBinary
      Call .Write(resp)
      Call .SaveToFile(path, adSaveCreateOverWrite)
      Call .Close()
    End With
End Sub

There are lots of ways this could be improved, at the moment the variables url and path are hardcoded but could be passed in using the WScript.Arguments collection, allowing you to pass the values as parameters of the script on the command line. Could also improve the error handling passing back the StatusText from HTTP request, but will leave this to you.

This is simply a bare bones example, intended to be built on.

Thanks! but your code doesn't work! I have created the folder c:\temp ,and create the file myscript.vbs on c:\ After I run cscript //nologo "c:\myscript.vbs" on Windows Command prompt, the system display only a Command windows ,just like https://www.dropbox.com/s/cw6vefvizbp6pja/Download.PNG?dl=0 — HelloCW, May 10 '17 at 15:08

How to rename a download file in client side programmatically?

1 Answers1