delphi - Scroll Horizontally on Mouse Movement smoothly

Question

I have a form with a horizontal scroll bar, but I want to remove the scroll bar by using mouse movement(horizaontally) on the form as a way to scroll. I want that with the movement of the mouse my form will scroll but without lag and smoothly and when I reach the end it stops scrolling. So if anyone could help me then that will be a huge help. Thanks in Advance.

Answer 1

This does the screen moving bit nicely on 10.1 Berlin as long as you don't hide the scroll bars. The documentation suggests it should work if you do hide the scroll bars, so maybe on an earlier version of Delphi it will.

OnMouseDown, OnMouseMove and OnMouseUp are used, and 3 local variables.

unit Unit10;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.StrUtils, Vcl.Mask;

type
  TForm10 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Button1: TButton;
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
  private
    { Private declarations }
    fIsDown : boolean;
    fX, fY : integer;
  public
    { Public declarations }
  end;

var
  Form10: TForm10;

implementation

{$R *.dfm}

procedure TForm10.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if Shift = [ssLeft] then  // if ONLY left down
  begin
    // Save co-ordinates
    fIsDown := TRUE;
    fX := X;
    fY := Y;
  end;
end;

procedure TForm10.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if Shift = [ssLeft] then  // if ONLY left down
  begin
    if fIsDown then
    begin
      HorzScrollBar.Position := HorzScrollBar.Position + fX - X;
      VertScrollBar.Position := VertScrollBar.Position + fY - Y;
    end
    else
    begin
      fIsDown := TRUE;
    end;
    fX := X;
    fY := Y;
  end
  else
  begin
    fIsDown := FALSE;
  end;
end;

procedure TForm10.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  fIsDown := FALSE; // regardless of shift state!
end;

end.

Please let us know if hiding the scroll bars works on XE8, as this would be useful for future readers.