XSLT: Using one Key to cross reference a second key

Question

I need to transform XML into a Table Grid which takes the format:

A1,B1,C1

A2,B2,C2

A3,B3,C3

The XML that I am working with provides one cell value per record, but each record supplies a DayOfWeek (column) and Stream(Row) value.

I have made a simple XSLT transform using two keys, one for Stream and one for DayOfWeek. These work successfully in that I have 3 rows, one for each stream, and 3 columns, one for each day of the week. However the content is just the first row repeated (i.e.

A1,B1,C1,
A1,B1,C1,
A1,B1,C1

How do I select DisplayStuff into a table cell based on both key criteria?

Here is my XSLT:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes" encoding="us-ascii" />
    <xsl:key name="DayOfWeek1" match="DataRow" use="DayOfWeek" />
    <xsl:key name="Stream1" match="DataRow" use="Stream" />
    <xsl:template match="QueryResults">
        <table>
    <xsl:for-each select="//DataRow[generate-id() = generate-id(key('Stream1',Stream)[1])]">
        <tr style="border: 1px solid black;" class="scrolling">
            <xsl:for-each select="//DataRow[generate-id() = generate-id(key('DayOfWeek1',DayOfWeek)[1])]">


                <td style="border: 1px solid black;" width="100px">
                    <xsl:value-of select="DisplayStuff" />
                </td>

            </xsl:for-each>
        </tr>
    </xsl:for-each>
    </table>
    </xsl:template>
</xsl:stylesheet>

XML:

<?xml version="1.0" encoding="UTF-8"?>
<QueryResults>
<DataRow>
    <Stream>1</Stream>
    <DayOfWeek>1</DayOfWeek>
    <DisplayStuff>A1</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>1</Stream>
    <DayOfWeek>2</DayOfWeek>
    <DisplayStuff>B1</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>1</Stream>
    <DayOfWeek>3</DayOfWeek>
    <DisplayStuff>C1</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>2</Stream>
    <DayOfWeek>1</DayOfWeek>
    <DisplayStuff>A2</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>2</Stream>
    <DayOfWeek>2</DayOfWeek>
    <DisplayStuff>B2</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>2</Stream>
    <DayOfWeek>3</DayOfWeek>
    <DisplayStuff>C2</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>3</Stream>
    <DayOfWeek>1</DayOfWeek>
    <DisplayStuff>A3</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>3</Stream>
    <DayOfWeek>2</DayOfWeek>
    <DisplayStuff>B3</DisplayStuff>
</DataRow>
<DataRow>
    <Stream>3</Stream>
    <DayOfWeek>3</DayOfWeek>
    <DisplayStuff>C3</DisplayStuff>
</DataRow>
</QueryResults>

Perhaps this is just a poor example, but if you know that you're dealing with a 3x3 (or 3xn) grid, why do you need keys at all? Just create a row for every group of 3 records and a cell for every record in that group - see, for example, https://stackoverflow.com/a/26573496/3016153. — michael.hor257k, Jul 14 '17 at 17:30
that's the issue. the table is dynamic. clinics can run up to 7 days a week and days don't have to be consecutive. there can be up to 10 clinic streams. — iainc, Jul 15 '17 at 23:31
that's the issue. the table is dynamic. clinics can run up to 7 days a week and days don't have to be consecutive. there can be up to 10 clinic streams. — iainc, Jul 15 '17 at 23:32

score 0 · Accepted Answer · answered Jul 16 '17 at 09:48

Try it this way?

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="row-by-day" match="DataRow" use="DayOfWeek" />
<xsl:key name="row-by-stream" match="DataRow" use="Stream" />

<xsl:template match="/QueryResults">
    <!-- a column for each distinct day of week  -->
    <xsl:variable name="columns" select="DataRow[generate-id() = generate-id(key('row-by-day', DayOfWeek)[1])]" />
    <table border="1">
        <!--  a row for each distinct stream -->
        <xsl:for-each select="DataRow[generate-id() = generate-id(key('row-by-stream', Stream)[1])]">
            <xsl:variable name="stream" select="key('row-by-stream', Stream)" />
            <tr>
                <!-- a cell for each column -->
                <xsl:for-each select="$columns">
                    <xsl:sort select="DayOfWeek" data-type="number" order="ascending"/>
                    <td>
                        <xsl:value-of select="$stream[DayOfWeek = current()/DayOfWeek]/DisplayStuff" />
                    </td>
                </xsl:for-each>
            </tr>
        </xsl:for-each>
    </table>
</xsl:template>

</xsl:stylesheet>

Note that this assumes there will be at most one DataRow for each intersection of Stream and DayOfWeek.

XSLT: Using one Key to cross reference a second key

1 Answers1