1

Here is the code:

@echo off
setlocal EnableDelayedExpansion
for /f "tokens=* skip=1 delims=\" %%b in ('wmic /node:%CompName% COMPUTERSYSTEM GET USERNAME') do echo %%b

Output:

domain\username
ECHO is off.

Expected result:

username

Notes: The variable CompName will be set prior. This can be ignored. This code is a part of a larger code I am writing for this batch file where I'll just need to pull the username to have it set as a variable.

Pseudo code:

set TargetUsername = (results from above)
future code (possibly used for other parts of the code)
Mofi
  • 46,139
  • 17
  • 80
  • 143
Jash
  • 31
  • 2
  • `tokens=*` prevents `for /F` from splitting a string into tokens; try with `tokens=1` instead; read the help of `for /?`! To prevent `echo` from returning the message `ECHO is off.` when it receives an empty string, write `echo(%%b`... – aschipfl Jul 17 '17 at 19:45
  • Setting it to token=2 fixed this, thank you. – Jash Jul 17 '17 at 19:54

2 Answers2

1

There are multiple issues causing ECHO is off. output on running the batch code.

The first one is using tokens=* which results in getting assigned to loop variable b always the entire line independent on delims=\ option.

The second issue is caused by the fact that wmic always outputs the data Unicode encoded using UTF-16 Little Endian format with byte order mark (BOM) with always a blank line at end of output. The command for fails to interpret the Unicode output correct as it interprets the last blank line as line having just a carriage return which is assigned to loop variable b too. This bug of for results in execution of echo with a carriage return which means echo without any parameter and the result is getting output the echo status. For details about wmic output and the wrong interpretation of last blank line by for see answers on How to correct variable overwriting misbehavior when parsing output?

The solution here is:

@echo off
for /F "skip=1 tokens=2 delims=\" %%I in ('%SystemRoot%\System32\wbem\wmic.exe /node:"%COMPUTERNAME%" COMPUTERSYSTEM GET USERNAME') do set "ComputerUserName=%%I"
echo Computer user name: %ComputerUserName%
echo Current user name:  %USERNAME%

The environment variable COMPUTERNAME is a predefined Windows environment variable.

The computer name can contain a space character and therefore it is recommended to enclose it in double quotes.

This batch code works because there is no second token when for interprets wrong the blank line at end of wmic Unicode output and therefore the command set is executed only once on processing all 3 lines of wmic output.

Mofi
  • 46,139
  • 17
  • 80
  • 143
0

I figured it out guys: I just set tokens=2:

Output:

username
Jash
  • 31
  • 2
  • The next thing is to set this information to a variable, I'll let anyone know if I run into any problems – Jash Jul 17 '17 at 19:57