How to copy multiple files in a folder into a single spreadsheet?

Question

I just started using excel macros. My problem is that I have 500 excel files in a folder. I am looking for a way to copy the first and second column of each of these 500 files into a single spreadsheet. Is this something that can be done using the excel VBA. Any help is appreciated. Please see the VBA code I recorded. How can I modify this to achieve my objective?

 Sub Macro1()
 '
 ' Macro1 Macro
 '

 '
    ActiveCell.Range("A1:B1").Select
    Range(Selection, Selection.End(xlDown)).Select
    Selection.Copy
    Windows("Book1").Activate
    ActiveSheet.Paste
End Sub

You'll want to [loop through files in a folder](https://stackoverflow.com/a/10380381/4650297). Open a file, set that as your workbook, copy column "A" and "B" into your main folder. **Use workbook and worksheet variables** to keep it all straight. Also, you'll likely need to *not* copy an entire column, but use `.End(xlDown)` (or `xlUp`) to get the range per worksheet, and copy that. There are myriad threads here on SO, and general sites on how to do this. Cobble something together and report back! — BruceWayne, Aug 07 '17 at 00:40

score 0 · Answer 1 · answered Aug 07 '17 at 01:40

Please read my comments within the code.

You have to correct your path(addresses), folder names and file names.

Option Explicit

Sub LoopAllFiles()
Dim myCalc As XlCalculation
Application.EnableCancelKey = xlDisabled
Application.ScreenUpdating = False
Application.Calculation = myCalc
Application.Calculation = xlCalculationManual
Dim folderPath As String
Dim Filename As String
Dim wb As Workbook, wbMaster As Workbook
Dim sh As Worksheet
Dim ColNo As Long
    ColNo = 1
folderPath = "C:\testfolder\" 'contains folder path
'or folderPath = "C:\Users\AshleyLarson\Desktop\LoopThroughFolders\AnyFolder\" 
' ==> Please correct your path otherwise code won't work. <==
If Right(folderPath, 1) <> "\" Then folderPath = folderPath + "\"
Filename = Dir(folderPath & "*.xlsx")
Do While Filename <> ""

    Set wb = Workbooks.Open(folderPath & Filename)
    Set wbMaster = Workbooks.Open(folderPath & "masterfolder\Master Template.xlsx")   ' BE CAREFUL This should be your Master File's path

    wb.Sheets(1).Range("A1:B" & (Range("A" & Rows.Count).End(xlUp).Row) + 100).Copy

    Workbooks("Master Template").Worksheets("Sheet1").Range(Chr(ColNo + 64) & ":" & Chr((ColNo + 1) + 64)).PasteSpecial xlPasteValues
    ColNo = ColNo + 2
    Application.DisplayAlerts = False
    Workbooks(Filename).Save
    Workbooks(Filename).Close
    Workbooks("Master Template.xlsx").Save
    Workbooks("Master Template.xlsx").Close
    Application.DisplayAlerts = True
    Filename = Dir
Loop
   Application.ScreenUpdating = True
   Application.Calculation = myCalc
End Sub

score 0 · Answer 2 · answered Aug 07 '17 at 02:04

This can be done in Power Query with just a few clicks on ribbon icons. No VBA required.

Start a new query

from file
navigate to folder
select all files
remove files you don't need with filters (optional step)
combine binaries
select the columns you want to keep

If the files in the folder change, just refresh the query.

Power Query is a free add-in from Microsoft for Excel 2010 and 2013 and built into Excel 2016 as Get & Transform.

score 0 · Answer 3 · answered Aug 08 '17 at 22:41

Try it this way.

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

https://www.rondebruin.nl/win/s3/win008.htm

How to copy multiple files in a folder into a single spreadsheet?

3 Answers3