expect script reading empty line

Question

I have a list of IPs that I am looping through to ssh into each of them and capture some logs. Currently, it will loop through all the IPs and do what I want, the issue occurs when it hits the last IP, after it is done with the last line, it attempts to spawn another empty line resulting in an error. (spawn ssh root@)

How can I prevent this error from happening?

myexpect.sh

set user user
set pass pass
set timeout 600

# Get the list of hosts, one per line #####
set f [open "/my/ip/list.txt"]
set hosts [split [read $f] "\n"]
close $f

# Iterate over the hosts
foreach host $hosts {
    spawn ssh $user@$host
    expect {
            "connecting (yes/no)? " {send "yes\r"; exp_continue}
            "assword: " {send "$pass\r"}
    }

    expect "# "
    send "myscript.sh -x\r"
    expect "# "
    send "exit\r"
    expect eof
}

myiplist.txt

172.17.255.255
172.17.255.254
...

error:

[root@172.17.255.255: ]# exit  //last ip in the list
Connection to 172.17.255.255 closed.
spawn ssh root@
ssh: Could not resolve hostname : Name or service not known
expect: spawn id exp5 not open

I think this has already been answered here: https://stackoverflow.com/questions/4165135/how-to-use-while-read-bash-to-read-the-last-line-in-a-file-if-there-s-no-new — Derek Brown, Oct 16 '17 at 23:31
In addition- I generally think using `expect + ssh` is a pain. You might want to try a tool like Ansible- it will make your life a lot easier. — Derek Brown, Oct 16 '17 at 23:31

score 3 · Accepted Answer · answered Oct 16 '17 at 23:59

Text files end with a newline

first line\n
...
last line\n

So when you read the whole file into a variable, then split on newlines, your list looks like this:

{first line} {...} {last line} {}

because there is an empty string after the last newline.

The idiomatic way to iterate over the lines of a file in Tcl/expect is this:

set f [open file r]
while {[gets $f host] != -1} {
    do something with $host
}
close $f

Or, use the -nonewline option of the read command

set f [open file]
set hosts [split [read -nonewline $f] \n]
close $f
foreach host $hosts {...}

Thank you, I used the `-nonewline` and it worked like a charm! — tiger_groove, Oct 17 '17 at 16:47

expect script reading empty line

1 Answers1