Copy object properties to another object in Groovy

Question

I was using a funky way to do it suggested in: https://stackoverflow.com/a/9072974/4470135 So my code is:

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.properties*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

What I get when I try to call a method that should convert an Entity into a Dto is:

No signature of method: java.util.ArrayList.keySet() is applicable for argument types: () values: []\nPossible solutions: toSet(), toSet(), set(int, java.lang.Object), set(int, java.lang.Object), get(int), get(int)

UPDATE:

My source is a Serializable bean with fields:

private String passengerName;
@NotNull
@Size(min = 5, max = 40)
private String destination;
@NotNull
private String departureDate;

My target is a JPA Entity with the same fields, but with an additional @Id field and a slightly different date representation:

@DateTimeFormat(iso = DateTimeFormat.ISO.DATE_TIME)
ZonedDateTime departureDate

Could you paste your Entity and Dto classes? Also showing a sample of copying one to another would be helpful. — Szymon Stepniak, Oct 26 '17 at 12:25
It might be something to do with the way you are calling `copyProperties`. I mashed your version with the original thread and it worked fine. — Michael Easter, Oct 26 '17 at 18:29
I'd go with the first version on that post anyway. `properties` also returns the values (e.g. expensive getters). — cfrick, Oct 26 '17 at 21:16

score 4 · Answer 1 · answered Feb 12 '21 at 23:06

4

User user = User.findById('1')
User copyUser = new User()
InvokerHelper.setProperties(copyUser, user.properties)

answered Feb 12 '21 at 23:06

Bruno Tonini

39
2

Mene · Accepted Answer · 2017-10-27T16:41:22.933

The code is working, however, there are corner cases where it may break.

To fix this replace the property access properties with the method call getProperties(), which might be enough for your case. To cover all cases, you will need to write code for special cases (see bottom)

Working example for the original version

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.properties*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

def a = new Expando()
a.foo = "foo"
a.bar = "bar"

def b = new Expando()
b.baz = "baz"
b.bar = "old"

copyProperties(a, b)

println b

Example causing problems

If the parameters have a property called properties I get the same exception you got (if the value is a List):

def c = new Expando()
c.properties = []
c.bar = "bar"

def d = new Expando()
d.baz = "baz"
d.bar = "old"

copyProperties(c, d)

println d

What works in both cases:

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.getProperties()*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

Not that here I used an explicit call to getProperties rather than just accessing the properties property.

We can still break this

def e = new Object() {
    // causes same Exception again
    def getProperties() {
        return []
    }

    def bar = "bar"
}

def f = new Expando()
f.baz = "baz"
f.bar = "old"

copyProperties(e, f)

You can fix the last example for e by using the metaClass explicitly

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.getMetaClass()*.properties*.name
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

However, that will fail due to f.

Handle special cases

def getProperties(Expando obj) {
    return obj.getProperties().keySet()
}

def getProperties(Object obj) {
    return obj.getMetaClass()*.properties*.name
}

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target].collect {getProperties(it)}
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

Here we give objects that need a special treatment what they need ;) Note that this only works like this for groovy with @CompileDynamic as the decision which getProperties implementation is called will be made at runtime. The alternative is a check with instanceof for all the cases.

What a detailed answer! Thanks, @Mene! – yuranos Oct 27 '17 at 20:36 — yuranos, Oct 27 '17 at 20:36

Copy object properties to another object in Groovy

2 Answers2

Linked