Ratpack: define routes reading from a list

Question

I want to create a "mock" server using Ratpack.

First, I'm reading from a folder and defining a list of pairs, each pair has:

• A path
• The mock response for that path

I want to launch a server that defines those routes and responses:

---

// this is already done; returns smth such as:
def getServerRules() {
  [ path: "/books", response: [...] ],
  [ path: "/books/42", response: [ title: "this is a mock" ] ],
  [ path: "/books/42/reviews", response: [ ... ] ],
  ...
]

def run() {
 def rules = getServerRules()
 ratpack {
   handlers {
     get( ??? rule.path ??? ) {
       render json( ??? rule.response ??? )
     }
   }
 }
}

Can I iterate over those rules in order to define a handler for each item somehow?

Answer 1

You can define all your handlers by iterating over a list of defined server rules, something like in this Ratpack Groovy script:

@Grapes([
        @Grab('io.ratpack:ratpack-groovy:1.5.0'),
        @Grab('org.slf4j:slf4j-simple:1.7.25'),
        @Grab('org.codehaus.groovy:groovy-all:2.4.12'),
        @Grab('com.google.guava:guava:23.0'),
])

import static ratpack.groovy.Groovy.ratpack
import static ratpack.jackson.Jackson.json

def getServerRules() {
    [
            [path: "", response: "Hello world!"],
            [path: "books", response: json([])],
            [path: "books/42", response: json([title: "this is a mock"])],
            [path: "books/42/reviews", response: json([])],
    ]
}

ratpack {
    handlers {
        getServerRules().each { rule ->
            get(rule.path) {
                render(rule.response)
            }
        }
    }
}

As you can see all handlers are defined inside for-each loop that iterates over predefined server rules. Two things worth mentioning:

• don't start your URL paths with "/" in the beginning, otherwise endpoint wont get defined
• if you want to return JSON response wrap your response body with ratpack.jackson.Jackson.json(body) method, similarly to what I did in the example

Output

curl localhost:5050
Hello World!

curl localhost:5050/books
[]

curl localhost:5050/books/42
{"title":"this is a mock"}

curl localhost:5050/books/42/reviews
[]

I hope it helps.