Code works during F8 step through, but not when run normally

Question

Sub InternetPractice()

    Dim ie As InternetExplorer

    Set ie = New InternetExplorer

    ie.Visible = True

    ie.navigate "https://www.yahoo.com"

    Do While ie.Busy = True Or ie.readyState <> 4: DoEvents: Loop

    ie.document.getElementById("uh-search-box").Value = "Earth"
    ie.document.getElementById("uh-search-button").Click

    Do While ie.Busy = True Or ie.readyState <> 4: DoEvents: Loop

    ie.document.getElementById("logo").Click

    Set ie = Nothing

End Sub

The code works when I step through it line by line, but not when run normally. I have tried inserting up to 45 second breaks in certain parts with no success.

Running normally, the code breaks during ie.document.getElementById("logo").Click and gives me a

'424' object required error

So when you run it normally, does anything appear to happen? — Robby, Nov 08 '17 at 17:07
I get '424' object required run time error after loading the yahoo search — T Doe, Nov 08 '17 at 17:08
Consider using a better API: https://stackoverflow.com/a/17481643/1188513 — Mathieu Guindon, Nov 08 '17 at 17:13
Thanks for the suggestion. I am not familiar with that, but it seems much faster. I will have to check it out! — T Doe, Nov 08 '17 at 18:36

K.Dᴀᴠɪs · Accepted Answer · 2017-11-08T17:47:43.320

Because this is an issue where the object is not yet available, the easiest way to fix your problem is to set logo as an object first - looping until it is Not Nothing, then click it.

Option Explicit

Sub InternetPractice()

    Dim ie As New InternetExplorer, logoBtn As Object

    With ie
        .Visible = True
        .navigate "https://www.yahoo.com"
        Do While .Busy Or .readyState <> 4: DoEvents: Loop
        .document.getElementById("uh-search-box").Value = "Earth"
        .document.getElementById("uh-search-button").Click
        Do While .Busy = True Or .readyState <> 4: DoEvents: Loop
        On Error Resume Next
        Do While logoBtn Is Nothing
            Set logoBtn = .document.getElementById("logo")
            DoEvents
        Loop
        On Error Goto 0
    End With
    logoBtn.Click

End Sub

So you are essentially replacing this line:
ie.document.getElementById("logo").Click

with this:

    Dim logoBtn As Object
    Do While logoBtn Is Nothing
        Set logoBtn = ie.document.getElementById("logo")
        DoEvents
    Loop
    logoBtn.Click

Even after readyState = Complete, in some cases objects are not fully initialized. This can be due in part to having multiple iFrames that do their own thing apart from the main HTML page you see.

score 1 · Answer 2 · answered Nov 08 '17 at 17:59

I agree with K.Davis, the Ready State is not always reliable. Try this:

Do While ie.Busy = True Or ie.readyState <> 4: DoEvents: Loop
Sleep(100)
Do While ie.Busy = True Or ie.readyState <> 4: DoEvents: Loop

Code works during F8 step through, but not when run normally

2 Answers2