Camel case converter in an excel

Question

I am trying to convert a field in an excel sheet (e.g. REC_LEN) to camel case. I am using this formula to do that

=LEFT(A1) & RIGHT(SUBSTITUTE(PROPER(A1),"_",""), LEN( SUBSTITUTE(A1,"_",""))-1)

This is giving me results like RecLen. I want to convert my first letter to lowercase too (The expected output is recLen). Can somebody help me out with this? I am not too familiar with excel formulae. Not sure if this has been already asked before but any help is much appreciated.

Scott Craner · Accepted Answer · 2023-02-10T19:47:37.170

28

Try this:

=LOWER(LEFT(A1)) & MID(SUBSTITUTE(PROPER(A1),"_",""),2,LEN(A1))

With Office 365 we can use:

=LET(
    rr,A1,
    x,TEXTSPLIT(rr,"_"),
    CONCAT(LOWER(TAKE(x,,1)),PROPER(DROP(x,,1))))

edited Feb 10 '23 at 19:47

answered Nov 14 '17 at 13:53

Scott Craner

148,073
10
49
81

Thank you! but this does not work for fields with multiple underscores. Like LAST_UPDT_DT. – Twisha Nov 14 '17 at 13:56

score 5 · Answer 2 · answered Nov 09 '20 at 07:54

5

Just use =PROPER(A1) on the another cell and you have it done.

answered Nov 09 '20 at 07:54

Baraka Mbega

69
1
2

1

The OP intended to lower case the first letter and remove underscores, which using Proper alone does not do. – General Grievance Nov 09 '20 at 13:13

score 3 · Answer 3 · answered Apr 21 '22 at 04:18

3

You were so close! Just wrap your left expression in a LOWER:

=LOWER(LEFT(A1)) & RIGHT(SUBSTITUTE(PROPER(A1),"_",""), LEN( SUBSTITUTE(A1,"_",""))-1)

answered Apr 21 '22 at 04:18

Chris Schaller

13,704
3
43
81

score 1 · Answer 4 · answered Oct 01 '19 at 18:17

1

   =LOWER(LEFT(A1)) & MID(A1,2,LEN(A1))

This works perfectly for creating camel case when there is no space or underscore between words.

So HelloWorld will become helloWorld.

answered Oct 01 '19 at 18:17

Jobin

79
3
8

score 0 · Answer 5 · edited Apr 07 '23 at 16:10

0

This converts to camel case:

=SUBSTITUTE(LOWER(LEFT(A5)) & MID(A5,2,LEN(A5)),"_","")

edited Apr 07 '23 at 16:10

nullromo

2,165
2
18
39

answered Mar 31 '23 at 14:23

Niki

1

While this code snippet may be the solution, including a detailed explanation really helps to improve the quality of your post. Remember that you are answering the question for readers in the future, and those people might not know the reasons for your code suggestion. – Shawn Hemelstrand Apr 01 '23 at 02:12

naresh gautam · Answer 6 · 2020-09-23T05:03:28.860

-1

using replace,

=LOWER(LEFT(A1,FIND("_",A1)-1))&PROPER(REPLACE(A1,1,FIND("_",A1),""))

edited Sep 23 '20 at 05:03

answered Sep 23 '20 at 04:57

naresh gautam

15
6

Camel case converter in an excel

6 Answers6

Linked

Related